ASP个人网站与动网整合非官方方法_应用技巧

虽然动网已提供有详细的"动网论坛系统Api接口开发人员指南"，但像我这样的菜鸟一时半会可是参详不透的，汗。不甘心，在对其登录、验证等函数进行一番研究再加以测试后最终竟也小有所成，菜鸟也有菜鸟的办法: 

本次测试的论坛版本为Version 7.1.0 Sp1，未对其他版本做进行测试 

一、网站文件结构 

wwwroot 
  ┝ index.asp 
  ┝ CheckUserLogin.asp 
  ┕ bbs/ 

二、整合原理 

对于同步更新实现不困难，整合主要问题就是难在同步登录，所以我们的重点都将放在讨论如何实现同步登录上。我的方法是将主站用户表整合至动网用户表Dv_User中(免去以后得更新两个库的麻烦)，可按需要在Dv_User新增字段，并对bbs/login.asp和bbs/inc/Dv_ClsMain.asp做适当的修改；登录时将表单发至bbs/login.asp进行验证；主站根据动网登录成功后在Session记录的信息判断是否登录成功，并取得用户资料。 

三、新增修改文件 

1.index.asp code: 

<html> 
<head> 
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> 
<title>个人网站与动网整合(www.mzwu.com)</title> 
</head> 

<body> 
<!--#include file="CheckUserLogin.asp" --> 
<% 
If CheckUserLogin Then 
    Response.write("<a href=""bbs/logout.asp?back=1"">退出登陆</a><p></p>") 
    Response.write("用户名:" & Request.Cookies("username") & "<br>") 
    Response.write("性别:" & Request.Cookies("sex") & "<br>") 
    Response.write("注册时间:" & Request.Cookies("joindate") & "<br>") 
    Response.write("最后登录:" & Request.Cookies("lastlogin") & "<br>") 
    Response.write("登录次数:" & Request.Cookies("userlogins") & "<br>") 
    Response.write("浏览器类型:" & Request.Cookies("browser") & "<br>") 
    Response.write("浏览器版本:" & Request.Cookies("version") & "<br>") 
    Response.write("操作系统:" & Request.Cookies("platform") & "<br>") 
Else 
%> 
<form id="form1" name="form1" method="post" action="bbs/login.asp?action=chk&back=1"> 
  用户名： 
    <input name="username" type="text" id="username" size="10" /> 
    <br /> 
    密  码： 
    <input name="password" type="password" id="password" size="10" /> 
    <input type="submit" name="Submit" value="登录" /> 
</form> 
<% 
End if 
%> 
<p></p><a href="bbs/">进入论坛</a> 
</body> 
</html> 

2.CheckUserLogin.asp code: 

<!--#Include File="bbs/inc/Dv_ClsMain.asp"--> 
<% 
Function CheckUserLogin() 
    Dim Dvbbs,UserSession 
    Const MsxmlVersion=".3.0" 
    Set Dvbbs = New Cls_Forum 
    Set UserSession=Server.CreateObject("msxml2.FreeThreadedDOMDocument"& MsxmlVersion) 
    If UserSession.loadxml(Session(Dvbbs.CacheName & "UserID")&"") Then 
        If UserSession.documentElement.selectSingleNode("userinfo/@userid").text<>"0" Then 
            '在论坛登录成功 
            CheckUserLogin = True 
            '下边是用户一些信息的获取方法，可自行将其保存于Cookies或Session中便于使用: 
            '用户ID      :  UserSession.documentElement.selectSingleNode("userinfo/@userid").text 
            '用户名      :  UserSession.documentElement.selectSingleNode("userinfo/@username").text 
            '生日        :  UserSession.documentElement.selectSingleNode("userinfo/@userbirthday").text 
            '电子邮箱    :  UserSession.documentElement.selectSingleNode("userinfo/@useremail").text 
            '性别        :  UserSession.documentElement.selectSingleNode("userinfo/@usersex").text  '0为女,1为男 
            '注册时间    :  UserSession.documentElement.selectSingleNode("userinfo/@joindate").text 
            '最后登录    :  UserSession.documentElement.selectSingleNode("userinfo/@lastlogin").text 
            '登录次数    :  UserSession.documentElement.selectSingleNode("userinfo/@userlogins").text 
            '金钱        :  UserSession.documentElement.selectSingleNode("userinfo/@userwealth").text 
            '积分        :  UserSession.documentElement.selectSingleNode("userinfo/@userep").text 
            '魅力        :  UserSession.documentElement.selectSingleNode("userinfo/@usercp").text 
            '最后登录IP  :  UserSession.documentElement.selectSingleNode("userinfo/@userlastip").text 
            '浏览器类型  :  UserSession.documentElement.selectSingleNode("agent/@browser").text 
            '浏览器版本  :  UserSession.documentElement.selectSingleNode("agent/@version").text 
            '操作系统    :  UserSession.documentElement.selectSingleNode("agent/@platform").text 
            '来访IP      :  UserSession.documentElement.selectSingleNode("agent/@ip").text 
            '举例应用: 
            Response.Cookies("username") = UserSession.documentElement.selectSingleNode("userinfo/@username").text 
            Response.Cookies("joindate") = UserSession.documentElement.selectSingleNode("userinfo/@joindate").text 
            If UserSession.documentElement.selectSingleNode("userinfo/@usersex").text="0" Then 
                Response.Cookies("sex") = "靓妹" 
            Else 
                Response.Cookies("sex") = "酷哥" 
            End if 
            Response.Cookies("lastlogin") = UserSession.documentElement.selectSingleNode("userinfo/@lastlogin").text 
            Response.Cookies("userlogins") = UserSession.documentElement.selectSingleNode("userinfo/@userlogins").text 
            Response.Cookies("browser") = UserSession.documentElement.selectSingleNode("agent/@browser").text 
            Response.Cookies("version") = UserSession.documentElement.selectSingleNode("agent/@version").text 
            Response.Cookies("platform") = UserSession.documentElement.selectSingleNode("agent/@platform").text 
        Else 
            '访问过论坛尚未登录，为来宾状态 
            CheckUserLogin = False 
        End if 
    Else 
        '未访问过论坛 
        CheckUserLogin = False 
    End if 
    Set UserSession = nothing 
    Set Dvbbs = nothing 
End Function 
%> 

3.bbs/login.asp新增红色部分，使在站点首页登录成功后仍能返回首页: 

    Dim comeurlname 
    If instr(lcase(request("comeurl")),"reg.asp")>0 or instr(lcase(request("comeurl")),"login.asp")>0 or trim(request("comeurl"))="" Then 
        comeurlname="" 
        comeurl="index.asp" 
    Else 
        comeurl=request("comeurl") 
        comeurlname="<li><a href="&request("comeurl")&">"&request("comeurl")&"</a></li>" 
    End If 

    If request("back")="1" Then 
        Response.Redirect("../index.asp") 
    End If 

    Dim TempStr 
    TempStr = template.html(2) 
    'If Dvbbs.Forum_ChanSetting(0)=1 And Dvbbs.Forum_ChanSetting(10)=1 And Dvbbs.Forum_ChanSetting(12)=1 Then 
    '    TempStr = Replace(TempStr,"{$ray_logininfo}",template.html(3)) 
    'Else 
    '    TempStr = Replace(TempStr,"{$ray_logininfo}","") 
    'End If 
    '----------------------------------------------------------------- 
    '系统整合 
    '----------------------------------------------------------------- 
    If DvApi_Enable Then 
        Response.Write DvApi_SaveCookie 
        Response.Flush 
    End If 
    '----------------------------------------------------------------- 
    TempStr = Replace(TempStr,"{$ray_logininfo}","") 
    TempStr = Replace(TempStr,"{$comeurl}",comeurl) 
    TempStr = Replace(TempStr,"{$comeurlinfo}",comeurlname) 
    TempStr = Replace(TempStr,"{$forumname}",Dvbbs.Forum_Info(0)) 
    Response.Write TempStr 
    TempStr="" 
End Function 

4.bbs/logout.asp新增红色部分，使在站点首页点退出登录后仍能返回首页: 

    '----------------------------------------------------------------- 
    '系统整合 
    '----------------------------------------------------------------- 
    Dim DvApi_Obj,DvApi_SaveCookie,SysKey 
    If DvApi_Enable Then 
        Md5OLD = 1 
        SysKey = Md5(Dvbbs.MemberName&DvApi_SysKey,16) 
        Md5OLD = 0 
        Set DvApi_Obj = New DvApi 
            DvApi_SaveCookie = DvApi_Obj.SetCookie(SysKey,Dvbbs.MemberName,"","") 
        Set DvApi_Obj = Nothing 
        Response.Write DvApi_SaveCookie 
        Response.Flush 
    End If 

    If request("back")="1" Then 
        Response.Redirect("../index.asp") 
    End If 

    '----------------------------------------------------------------- 
    'Response.Redirect Dvbbs.Forum_Info(11) 
    response.write"<script language=JavaScript>" 
    response.write"setTimeout(""window.location='"&Dvbbs.Forum_Info(11)&"'"",1000);" 
    response.write"</script>" 

四、动网设置：去掉登录验证码，OK，整合完毕。 

五、扩展： 

默认Dv_User表中的字段有些时候并不能满足我们的实际需求，我们就需要新增字段对其进行扩展，动手吧： 
1.打开Dv_User表新增一文本类型字段info_1 
2.bbs/login.asp的ChkUserLogin函数中 
Sql="Select UserID,UserName,UserPassword,UserEmail,UserPost,UserTopic,UserSex,UserFace,UserWidth,UserHeight,JoinDate,LastLogin,lastlogin as cometime , LastLogin as activetime,UserLogins,Lockuser,Userclass,UserGroupID,UserGroup,userWealth,userEP,userCP,UserPower,UserBirthday,UserLastIP,UserDel,UserIsBest,UserHidden,UserMsg,IsChallenge,UserMobile,TitlePic,UserTitle,TruePassWord,UserToday,UserMoney,UserTicket,FollowMsgID,Vip_StarTime,Vip_EndTime,userid as boardid" 
修改为： 
Sql="Select UserID,UserName,UserPassword,UserEmail,UserPost,UserTopic,UserSex,UserFace,UserWidth,UserHeight,JoinDate,LastLogin,lastlogin as cometime , LastLogin as activetime,UserLogins,Lockuser,Userclass,UserGroupID,UserGroup,userWealth,userEP,userCP,UserPower,UserBirthday,UserLastIP,UserDel,UserIsBest,UserHidden,UserMsg,IsChallenge,UserMobile,TitlePic,UserTitle,TruePassWord,UserToday,UserMoney,UserTicket,FollowMsgID,Vip_StarTime,Vip_EndTime,userid as boardid,info_1" 
3.bbs/inc/Dv_ClsMain.asp的TrueCheckUserLogin函数中 
Sql="Select UserID,UserName,UserPassword,UserEmail,UserPost,UserTopic,UserSex,UserFace,UserWidth,UserHeight,JoinDate,LastLogin as cometime ,LastLogin,LastLogin as activetime,UserLogins,Lockuser,Userclass,UserGroupID,UserGroup,userWealth,userEP,userCP,UserPower,UserBirthday,UserLastIP,UserDel,UserIsBest,UserHidden,UserMsg,IsChallenge,UserMobile,TitlePic,UserTitle,TruePassWord,UserToday,UserMoney,UserTicket,FollowMsgID,Vip_StarTime,Vip_EndTime,userid as boardid" 
修改为： 
Sql="Select UserID,UserName,UserPassword,UserEmail,UserPost,UserTopic,UserSex,UserFace,UserWidth,UserHeight,JoinDate,LastLogin as cometime ,LastLogin,LastLogin as activetime,UserLogins,Lockuser,Userclass,UserGroupID,UserGroup,userWealth,userEP,userCP,UserPower,UserBirthday,UserLastIP,UserDel,UserIsBest,UserHidden,UserMsg,IsChallenge,UserMobile,TitlePic,UserTitle,TruePassWord,UserToday,UserMoney,UserTicket,FollowMsgID,Vip_StarTime,Vip_EndTime,userid as boardid,info_1" 
4.CheckUserLogin.asp中 
Response.Cookies("platform") = UserSession.documentElement.selectSingleNode("agent/@platform").text 
后添加 
Response.Cookies("info_1") = UserSession.documentElement.selectSingleNode("userinfo/@info_1").text 
5.index.asp中 
Response.write("操作系统:" & Request.Cookies("platform") & "<br>") 
后添加 
Response.write("新增:" & Request.Cookies("info_1") & "<br>") 
6.OK，圆满完成 

时间： 2024-10-11 21:55:36

ASP个人网站与动网整合非官方方法_应用技巧的相关文章

ASP个人网站与动网整合非官方方法

虽然动网已提供有详细的"动网论坛系统Api接口开发人员指南",但像我这样的菜鸟一时半会可是参详不透的,汗.不甘心,在对其登录.验证等函数进行一番研究再加以测试后最终竟也小有所成,菜鸟也有菜鸟的办法: 本次测试的论坛版本为Version 7.1.0 Sp1,未对其他版本做进行测试 一.网站文件结构 wwwroot    ┝ index.asp    ┝ CheckUserLogin.asp    ┕ bbs/ 二.整合原理 对于同步更新实现不困难,整合主要问题就是难在同步登录,所以我们的

ASP类型网站结合动网论坛会员的方法第1/3页

个人网站如有会员注册模块+动网论坛的话,那网站要与动网论坛系统整合,实现不同Web系统之间的用户信息同步更新.登录等操作就不是件容易的事了,虽然动网已提供有详细的"动网论坛系统Api接口开发人员指南",但像我这样的菜鸟一时半会可是参详不透的,汗.不甘心,在对其登录.验证等函数进行一番研究再加以测试后最终竟也小有所成,菜鸟也有菜鸟的办法,哈哈. 一.网站文件结构 wwwroot   ┝ index.asp   ┝ CheckUserLogin.asp   ┕ bbs/ 二.整合原理 对于

使用ASP实现网站的“目录树”管理的代码_应用技巧

使用ASP实现网站的目录树 数据库结构(共使用了两个表)1.tblCategory字段名  类型   Root   binary   说明树关或开(目录的根)ID     自动编号 关键字Sort   integer  识别该字段内容的整数(如果root是开状态sort为0)表示显示的目录的顺序Name   text(255)可以包含html中的标识符HREF   text(255) 允许空 2.tblPagesID   自动编号 Sort  integer 关键字Name  text(255)

ASP中实现分页显示的七种方法_应用技巧

在微软的ASP编程体系中,ADO对象的建立,使得从网页访问数据库成为一件易事,特别是ADO的Recordset对象使得控制数据的输出显示更为方便.自由.而在Visual InterDev6.0(以下简称VI6.0)中,由于Script Object Model(以下简称SOM).Design-Time Control(以下简称DTC)以及Data Environment Object Model(以下简称DEOM)等对象模型的引入,使网页对数据库的访问设计显得更为方便. 因为主题方面的原因,关于

ASP.NET连接 Access数据库的几种方法_实用技巧

web.config 第一种方法: <?xml version="1.0" encoding="utf-8"?> <!-- 有关如何配置 ASP.NET 应用程序的详细消息,请访问 http://go.microsoft.com/fwlink/?LinkId=169433 --> <configuration> <appSettings> <add key="AccessConnString"

asp.net简单页面控件赋值实现方法_实用技巧

本文实例讲述了asp.net简单页面控件赋值的方法.分享给大家供大家参考,具体如下: /// <summary> /// 赋值 表名,控件名,要查询的唯一数据 /// </summary> protected void SetEvaluate(string TableName, string UpName, string Id) { ContentPlaceHolder cph = (ContentPlaceHolder)Page.Master.FindControl("

asp.net调用系统设置字体文本框的方法_实用技巧

本文实例展示了asp.net调用系统设置字体文本框的方法,是进行web开发中很实用的技巧.具体实现步骤如下: 一.调用系统字体文本框 首先在bin文件夹右击-->添加引用-->.net标签里选择:System.Windows.Forms-->确定 然后在cs文件里引入: using System.Windows.Forms; 添加如下代码: FontDialog fd = new FontDialog(); fd.ShowDialog().ToString(); 就可以调出系统设置字体的

asp.net GridView中使用RadioButton单选按钮的方法_实用技巧

本文实例讲述了asp.net GridView中使用RadioButton单选按钮的方法.分享给大家供大家参考,具体如下: 在GridView里做单选按钮,我用了三种方法 第一种方法:在GridView的模版列里加服务器端控件RadioButton,使用js控制单选 使用模版列里加RadioButton <script type="text/javascript"> function setRadio(nowRadio) { var myForm,objRadio; myF

asp.net实现中英文多域名检测的方法_实用技巧

本文实例讲述了asp.net实现中英文多域名检测的方法.分享给大家供大家参考,具体如下: 第一步:在前台页面中写入js代码和相关控件 /****写入js代码****/ <%-- 域名检测 --%> <script type="text/javascript"> //判断输入的是否为中文域名 function IsChDomain(domainStr) { var flag = false; var compStr = "ABCDEFGHIGKLMNOP