SQL Server 中的时间算法

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--前一天，给定日期的前一天

　　SELECT DATEADD(DAY,-1,@Date) AS '前一天'

　　--后一天，给定日期的后一天

　　SELECT DATEADD(DAY,1,@Date) AS '后一天'

　　GO

　　--月初，计算给定日期所在月的第一天

　　--这个计算的技巧是先计算当前日期到“1900-01-01”的时间间隔数，然后把它加到“1900-01-01”上来获得特殊的日期，这个技巧可以用---来计算很多不同的日期。

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01') AS '所在月的第一天'

　　--精简算法，根据SQL Server的时间表示方式可知，'1900-01-01' 可以用0代替

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) AS '所在月的第一天'

　　--上面两种算法精确到天 时分秒均为00:00:00.000

　　--下面算法课以保留时分秒

　　--思路：用给定日期减去月第一天与给定日期差的天数

　　SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)

　　GO

　　--月末，计算给定日期所在月的最后一天

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--思路：当前月的下一月1号在减1天

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')) AS '所在月的最一天'

　　SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')-1 AS '所在月的最一天'

　　--1900-01-01 用0代替

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)) AS '所在月的最一天'

　　SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)-1 AS '所在月的最一天'

　　--思路：与月初计算思路相同

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1989-12-31',@Date),'1989-12-31') AS '所在月的最一天'

　　--精简算法，'1989-12-31' 用-1代替

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1) AS '所在月的最一天'

　　--保留时分秒的算法

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)))

　　GO

　　--其他月计算

　　--计算给定日期所在月的上月第一天

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--当前月第一天减去一个月

　　SELECT DATEADD(MONTH,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月第一天'

　　--简化

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)-1,0) AS '上月第一天'

　　--另一种当前月第一天算法

　　SELECT DATEADD(MONTH,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月第一天'

　　GO

　　--计算给定日期所在月的上月最后一天

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--当前月第一天减去一天

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月最后一天'

　　--另一种当前月第一天算法

　　SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'

　　SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)-1 '上月最后一天'

　　--另一种算法，不能用当前月的最后一天加一个月，因为当前月可能是30天。

　　--例如 SELECT DATEADD(MONTH,1,'2010-06-30') --结果是2010-07-30而不是2010-07-31，

　　--这也是月末算法采用下月第一天减1天计算的原因

　　--但是如果计算月是31天择无此问题

　　--例如 SELECT DATEADD(MONTH,1,'2010-05-31') --结果是2010-06-30

　　--因此下面算法是正确的，-1 表示'1899-12-31 00:00:00.000'-- SELECT CONVERT(DATETIME,-1)

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)-1,-1)

　　--另一种当前月算法

　　SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'

　　--简化

　　SELECT DATEADD(DAY,0-DATEPART(DAY,@Date),@Date) '上月最后一天'

　　GO

　　--计算给定日期所在月的下月第一天

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--当前月第一天加一个月

　　SELECT DATEADD(MONTH,1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '下月第一天'

　　--简化

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+1,0) AS '下月第一天'

　　--另一种当前月第一天算法

　　SELECT DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '下月第一天'

　　GO

　　--计算给定日期所在月的下月最后一天

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--当前月第一天加2个月再减去1天

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))) AS '下月最后一天'

　　--简化

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)) AS '下月最后一天'

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)-1 AS '下月最后一天'

　　--另一种算法

　　SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)+1,-1) '下月最后一天'

　　--另一种当前月第一天算法

　　SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))) '下月最后一天'

　　GO

　　--所在星期的第一天，计算给定日期所在星期的第1天(星期日为第一天)

　　DECLARE @Date DATETIME

　　SET @Date= GETDATE()

　　--与SQL Server语言版本相关的算法

　　--思路：当前日期+星期日(每周的第1天)与当前日期的差的天数

　　--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

　　SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

　　SELECT DATEADD(WEEKDAY,1-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第一天，星期日'

　　--星期日，与SQL Server语言版本或@@DATEFIRST无关

　　--'1989-12-31' 是星期日，'1989-12-31' 再加上(当前日期与1989-12-31差的星期数)个星期

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),-1) AS '所在星期的星期日'

　　--或者

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),6) AS '所在星期的星期日'

　　GO

　　--所在星期的第二天，计算给定日期所在星期的第2天(星期日为第一天)

　　DECLARE @Date DATETIME

　　SET @Date= GETDATE()

　　--思路：当前日期+星期一(每周的第2天)与当前日期的差的天数

　　--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

　　SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

　　SELECT DATEADD(DAY,2-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第二天，星期一'

　　--星期一，与SQL Server语言版本或@@DATEFIRST无关

　　--'1900-01-01' 是星期一，'1900-01-01' 再加上(当前日期与1900-01-01差的星期数)个星期

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,@Date),0) AS '所在星期的星期一'

　　GO

　　--上个星期第一天，计算给定日期所在星期的上一个星期日(星期日为第一天)

　　DECLARE @Date DATETIME

　　SET @Date= GETDATE()

　　--思路：当前日志所在星期的星期日再减1周

　　--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

　　SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

　　SELECT DATEADD(WEEK,-1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上个星期第一天，星期日'

　　--一周等于7天

　　SELECT DATEADD(DAY,-7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上个星期第一天，星期日'

　　--简化

　　SELECT DATEADD(DAY,-6-DATEPART(WEEKDAY,@Date),@Date) AS '上个星期第一天，星期日'

　　--上个星期日，与SQL Server语言版本或@@DATEFIRST无关

　　SELECT DATEADD(WEEK,-1+DATEDIFF(WEEK,-1,@Date),-1) AS '上个星期日'

　　--或者

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),-1) AS '上个星期日'

　　GO

　　--下个星期第一天，计算给定日期所在星期的下一个星期日(星期日为第一天)

　　DECLARE @Date DATETIME

　　SET @Date= GETDATE()

　　--思路：当前日志所在星期的星期日再加1周

　　--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

　　SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

　　SELECT DATEADD(WEEK,1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下个星期第一天，星期日'

　　--一周等于7天

　　SELECT DATEADD(DAY,7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下个星期第一天，星期日'

　　--简化

　　SELECT DATEADD(DAY,8-DATEPART(WEEKDAY,@Date),@Date) AS '下个星期第一天，星期日'

　　--下个星期日，与SQL Server语言版本或@@DATEFIRST无关

　　SELECT DATEADD(WEEK,1+DATEDIFF(WEEK,-1,@Date),-1) AS '下个星期日'

　　--或者

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),6) AS '下个星期日'

　　GO

　　--判断给定日期是星期几

　　DECLARE @Date DATETIME

　　SET @Date= GETDATE()

　　--DATEPART(WEEKDAY,DATE)的返回值与@@DATEFIRST相关

　　SET DATEFIRST 7 -- 或者设置为美国英语SET LANGUAGE us_english; (星期日为第一天)

　　SELECT DATEPART(WEEKDAY,@Date) --返回值 1-星期日，2-星期一，3-星期二......7-星期六

　　--上面算法与SQL 语言版本或 @@DATEFIRST 相关

　　--下面算法与SQL Server语言版本或@@DATEFIRST无关

　　SELECT DATENAME(WEEKDAY,@Date) '星期'

　　GO

　　--年度计算

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--年初，计算给定日期所在年的第一天

　　SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) AS '所在年的第一天'

　　--年末，计算给定日期所在年的最后一天

　　SELECT DATEADD(YEAR,DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的最后一天'

　　--上一年年初，计算给定日期所在年的上一年的第一天

　　SELECT DATEADD(YEAR,DATEDIFF(YEAR,-0,@Date)-1,0) AS '所在年的上一年的第一天'

　　--上一年年末，计算给定日期所在年的上一年的最后一天

　　SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1) AS '所在年的上一年的最后一天'

　　--下一年年初，计算给定日期所在年的下一年的第一天

　　SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0) AS '所在年的下一年的第一天'

　　--下一年年末，计算给定日期所在年的下一年的最后一天

　　SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的下一年的最后一天'

　　GO

　　--季度计算

　　DECLARE @Date DATETIME

　　SET @Date=GETDATE()

　　--季度初，计算给定日期所在季度的第一天

　　SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) AS '当前季度的第一天'

　　--季度末，计算给定日期所在季度的最后一天

　　SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的最后一天'

　　--上个季度初

　　SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date)-1,0) AS '当前季度的上个季度初'

　　--上个季度末

　　SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的上个季度末'

　　--下个季度初

　　SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0) AS '当前季度的下个季度初'

　　--下个季度末

　　SELECT DATEADD(QUARTER,2+DATEDIFF(QUARTER,0,@Date),-1) AS '当前季度的下个季度末'

　　--计算给定日期所在月的天数

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　--本月度第一天与下月度第一天所差的天数

　　SELECT DATEDIFF(DAY,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0),DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0))

　　--借助变量简化

　　SELECT @Date = DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) --本月度第一天

　　SELECT DATEDIFF(DAY,@Date,DATEADD(MONTH,1,@Date))

　　--另一种思路：给定月最后一天的日期，记为本月天数

　　SELECT DAY(DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1))

　　GO

　　--计算给定日期所在季度的天数

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　--本季度第一天与下季度第一天所差的天数

　　SELECT DATEDIFF(DAY,DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0),DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0))

　　--借助变量简化

　　SELECT @Date = DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) --本季度第一天

　　SELECT DATEDIFF(DAY,@Date,DATEADD(QUARTER,1,@Date))

　　GO

　　--计算给定日期所在年度的天数

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　--本年度第一天与下年度第一天所差的天数

　　SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))

　　--借助变量简化

　　SELECT @Date = DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) --本年度第一天

　　SELECT DATEDIFF(DAY,@Date,DATEADD(YEAR,1,@Date))

　　GO

　　--判断给定日期所在年是否闰年

　　--根据全年总天数判断

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　SELECT CASE DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))

　　WHEN 365 THEN '平年' ELSE '闰年' END

　　--根据二月天数判断

　　--给日期的上一年最后一天加2个月，即为当年2月最后一天

　　SELECT CASE DAY(DATEADD(MONTH,2,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1))) WHEN 28 THEN '平年' ELSE '闰年' END

　　GO

　　--计算给定日期是当年的第几天

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　SELECT DATEPART(DAYOFYEAR,@Date) [DayOfYear];

　　SELECT DATENAME(DAYOFYEAR,@Date) [DayOfYear];

　　--另一种思路：当前日期与上年最后一天差的天数

　　SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1),@Date)[DayOfYear]

　　GO

　　--计算给定日期是当年的第几周

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　SELECT DATEPART(WEEK,@Date) [WeekOfYear]; --返回int型

　　SELECT DATENAME(WEEK,@Date) [WeekOfYear]; --返回varchar型

　　GO

　　--计算给定日期是当年的第几月

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　SELECT DATEPART(MONTH,@Date) [MonthOfYear]; --返回int型

　　SELECT DATENAME(MONTH,@Date) [MonthOfYear]; --返回varchar型

　　SELECT MONTH(@Date) [MonthOfYear];--返回int型

　　GO

　　--计算给定日期是当年的第几季度

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　SELECT DATEPART(QUARTER,@Date) [QuarterOfYear]; --返回int型

　　SELECT DATENAME(QUARTER,@Date) [QuarterOfYear]; --返回varchar型

　　GO

　　--计算给定日期是当月的第几周

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　--思路，给定日期是当年的第几周-给定日期所在月第一天是当年的第几周

　　SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))+1 [WeekOfMonth]

　　SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))+1 [WeekOfMonth]

　　GO

　　--计算给定日期所在月的第一个星期一是哪天

　　DECLARE @Date DATETIME;

　　SET @Date = GETDATE()

　　--思路，1900-01-01(星期一)加上(给定日志所在月的月6号与1900-01-01差的周数)个周

　　--为什么不选7号?如果是7号，那么7好恰好是星期日的话，第一个周一就会算到8号。

　　--为什么不选5号?如果5号是星期六，那么周一就跑到上月了。小于5号与这个道理一样。

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),0) '所在月的第一个星期一'

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),7) '所在月的第二个星期一'

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),1) '所在月的第一个星期二'

　　SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),8) '所在月的第二个星期二'

　　GO

时间： 2024-08-29 05:52:02

SQL Server 中的时间算法的相关文章

SQL Server 中的时间日期基本用法

 代码如下 复制代码 DECLARE @Date  DATETIME SET @Date=GETDATE() --前一天,给定日期的前一天 SELECT DATEADD(DAY,-1,@Date) AS '前一天' --后一天,给定日期的后一天 SELECT DATEADD(DAY,1,@Date) AS '后一天' GO --月初,计算给定日期所在月的第一天 --这个计算的技巧是先计算当前日期到"1900-01-01"的时间间隔数,然后把它加到"1900-01-01&quo

Sql Server中的日期与时间函数

Sql Server中的日期与时间函数: 1.  当前系统日期.时间     select getdate()  2. dateadd  在向指定日期加上一段时间的基础上,返回新的 datetime 值:   例如:向日期加上2天    select dateadd(day,2,'2004-10-15')  --返回:2004-10-17 00:00:00.000 3. datediff 返回跨两个指定日期的日期和时间边界数:   select datediff(day,'2004-09-01'

MS SQL Server中的 CONVERT 日期时间 格式化大全

出处:http://www.cnblogs.com/fernando/archive/2008/04/29/1176581.html  CONVERT 将某种数据类型的表达式显式转换为另一种数据类型.由于某些需求经常用到取日期格式的不同.现以下可在SQL Server中 将日期格式化. SQL Server 支持使用科威特算法的阿拉伯样式中的数据格式. 在表中,左侧的两列表示将 datetime 或 smalldatetime 转换为字符数据的 style 值. 给 style 值加 100,可

浅谈SQL Server中的快照

原文:浅谈SQL Server中的快照 简介     数据库快照,正如其名称所示那样,是数据库在某一时间点的视图.是SQL Server在2005之后的版本引入的特性.快照的应用场景比较多,但快照设计最开始的目的是为了报表服务.比如我需要出2011的资产负债表,这需要数据保持在2011年12月31日零点时的状态,则利用快照可以实现这一点.快照还可以和镜像结合来达到读写分离的目的.下面我们来看什么是快照.   什么是快照     数据库快照是 SQL Server 数据库(源数据库)的只读静态视图

谈一谈SQL Server中的执行计划缓存（上）

原文:谈一谈SQL Server中的执行计划缓存(上) 简介     我们平时所写的SQL语句本质只是获取数据的逻辑,而不是获取数据的物理路径.当我们写的SQL语句传到SQL Server的时候,查询分析器会将语句依次进行解析(Parse).绑定(Bind).查询优化(Optimization,有时候也被称为简化).执行(Execution).除去执行步骤外,前三个步骤之后就生成了执行计划,也就是SQL Server按照该计划获取物理数据方式,最后执行步骤按照执行计划执行查询从而获得结果.但查询

在SQL Server中实现最短路径搜索的解决方法_MsSql

开始这是去年的问题了,今天在整理邮件的时候才发现这个问题,感觉顶有意思的,特记录下来. 在表RelationGraph中,有三个字段(ID,Node,RelatedNode),其中Node和RelatedNode两个字段描述两个节点的连接关系:现在要求,找出从节点"p"至节点"j",最短路径(即经过的节点最少). 图1. 解析: 了能够更好的描述表RelationGraph中字段Node和 RelatedNode的关系,我在这里特意使用一个图形来描述,如图2. 图2

浅析SQL Server中的执行计划缓存(上)_MsSql

简介 我们平时所写的SQL语句本质只是获取数据的逻辑,而不是获取数据的物理路径.当我们写的SQL语句传到SQL Server的时候,查询分析器会将语句依次进行解析(Parse).绑定(Bind).查询优化(Optimization,有时候也被称为简化).执行(Execution).除去执行步骤外,前三个步骤之后就生成了执行计划,也就是SQL Server按照该计划获取物理数据方式,最后执行步骤按照执行计划执行查询从而获得结果.但查询优化器不是本篇的重点,本篇文章主要讲述查询优化器在生成执行计划之

浅析SQL Server中的执行计划缓存(上)

简介 我们平时所写的SQL语句本质只是获取数据的逻辑,而不是获取数据的物理路径.当我们写的SQL语句传到SQL Server的时候,查询分析器会将语句依次进行解析(Parse).绑定(Bind).查询优化(Optimization,有时候也被称为简化).执行(Execution).除去执行步骤外,前三个步骤之后就生成了执行计划,也就是SQL Server按照该计划获取物理数据方式,最后执行步骤按照执行计划执行查询从而获得结果.但查询优化器不是本篇的重点,本篇文章主要讲述查询优化器在生成执行计划之

在SQL Server 中使用SQLDMO

server   曾几何时,伙伴们为数据库的升级伤透了脑筋.往往程序的升级赶不上数据库的升级(版本控制的好,这也许不是什么问题,但对于很大一部分中国公司来说这是无法避免的).而有些n久以前的数据库要使用新程序的时候,数据库的升级简直就是无从下手.所以对比数据库升级的紧要性就逐渐的凸现出来.对于表和字段的升级按道理来说是不难的,通过sysobjects与syscolumns的比较很容易的可以找到不同之处,然后增加没有的对象即可.而对于视图和存储过程等非表对象的更新就有些为难了(当然视图和存储过程如