如何创建一个Cookie？
为了创建一个Cookie，您需要使用Response.Cookies命令。在下面的例子中，我们将创建一个名为“姓氏”，并指定值“someValue”，它的cookie：
<%
Response.Cookies("lastname") = "Peterson"
%>
该Response.Cookies命令必须出现在<HTML>标记，否则你需要放在网页顶部以下行：
<% response.buffer = true %>
也可以分配一个Cookie属性，比如设置一个日期时，在Cookie到期。下面的例子创建了一个cookie，将在30天届满的。如果你想在Cookie过期尽快离开你的访客，您必须设定值为1的Expires属性。
<%
Response.Cookies("lastname") = "Peterson"
Response.Cookies("lastname").Expires = Now + 30
%>
下一个重要属性是域属性。这个cookie只能读取域它源于。这是默认设置为其所在创建域，但您可以根据需要改变它。在有一个例子：
<%
Response.Cookies("lastname").Domain = "http://www.webcheatsheet.com"
%>
另外两个重要的属性是路径和安全性能。 Path属性指定的域，可以使用的cookie确切的路径。
如果安全属性被设置，那么cookie将只能设置浏览器是否使用安全套接字或https教程：/ /连接，但并不意味着该Cookie是安全的。它只是一个像所有其他的Cookie的文本文件。
在有一个例子：
<%
Response.Cookies("lastname").Path = "/cookies/"
Response.Cookies("lastname").Secure = True
%>
如何检索Cookie的值？
现在的Cookie设置，我们需要检索信息。为了获取cookie的值，需要使用Request.Cookies命令。在下面的例子，我们检索名为“姓氏”，并打印出其价值的cookie值。
<%
someValue = Request.Cookies("lastname")
response.write("The cookie value is " & someValue)
%>
输出将是“Cookie”。
使用Cookie字典
除了存储简单值，在Cookies集合cookie可以代表一个cookie字典。字典是一个构造类似于在这数组中的每个元素是由它的名字识别组成的数组。
基本上，饼干字典只是一个Cookie，它可以容纳几个值。这些值被称为键。这为您提供了一个cookie存储在您的所有必要的信息选项。例如，假设你要收集用户的姓名，存放在一个cookie他们。在下面的例子，我们将创建一个名为“用户”，将包含这些信息的Cookie
<%
Response.Cookies("user")("firstname") = "Andrew"
Response.Cookies("user")("lastname") = "Cooper"
%>
当你需要引用在与键的cookie的值，您必须使用键值。在有一个例子：
<%
Response.Write(Request.Cookies("user") ("firstname"))
Response.Write(Request.Cookies("user") ("lastname"))
%>
现在让我们假设我们要读取的所有您的服务器发送到用户的计算机上的Cookie。为了检查是否有一个cookie的键或不，您必须使用特定的cookie HasKeys财产。下面的示例演示如何做到这一点。
<%
Response.Cookies("lastname") = "Peterson"
Response.Cookies("user")("firstname") = "Andrew"
Response.Cookies("user")("lastname") = "Cooper"
%>
<%
'The code below iterates through the Cookies collection.
'If a given cookie represents a cookie dictionary, then
'a second, internal for...each construct iterates through
'it retrieving the value of each cookieKey in the dictionary.
Dim cookie
Dim cookieKey
for each cookie in Request.Cookies
if Request.Cookies(cookie).HasKeys Then
'The cookie is a dictionary. Iterate through it.
%>
The cookie dictionary <%=cookie%> has the
following values:<br />
<%
for each cookieKey in Request.Cookies(cookie)
%>
cookieKey: <%= cookieKey %><br />
Value:
<%=Request.Cookies(cookie)(cookieKey)%><br />
<%
next
else
'The cookie represents a single value.
%>
The cookie <%=cookie%> has the following value:
<%=Request.Cookies(cookie)%> <br />
<%
end if
next
%>