需求：
因为一直在做数据备份，每天繁琐的备份及删除，着实很麻烦。而且有时候哪天忘记删除备份的数据，而磁盘已经满了，那么当天的数据无法完全备份。而又假如哪天数据刚刚没备份好，而服务器又出了问题，然而这种事偏偏发生了，杯具。
所以现在想写了一些批处理命令，让系统每天进行备份并删除一个星期之前的数据，这样即省事，而且又不会忘记，毕竟机器只要设定好了，就是完全按照我们的意愿去做事了。下面就来分享下这几天的成果，献丑了。
首先看下系统日期格式：
注意此时系统的短日期格式为：yy/MM/dd,用下面的代码就可以实现获取当前日期以前任何一天的日期了，并且可以在系统里创建一个以获取的日期为名字的文件夹以做备份。代码如下：（此代码我在windows7下做的测试）
更多精彩内容：http://www.bianceng.cnhttp://www.bianceng.cn/OS/skills/
@echo off
rem 计算指定天数之前的日期
set DaysAgo=7
rem 假设系统日期的格式为yy/MM/dd,一定要注意系统格式，不然可能出错
call :DateToDays %date:~0,4% %date:~4,2% %date:~6,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%%DstMonth%%DstDay%
echo %DaysAgo%天前的日期是%DstDate%
set TargetDriver=C:\
rem 在C盘创建一个以获取的日前为名字的文件夹，如20120627
MD %TargetDriver%%DstDate%
goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
rem set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
把上面的代码复制保存为.bat文件即可使用。
另外：
假如日期格式为：yyyy-MM-dd，则上面第5行代码应该改为如下：
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDay
测试过在XP下也有所改动，在server服务器里也会不大一样，所以想要做到举一反三，还是得看懂上面代码中一句的意思：
call :DateToDays %date:~0,4% %date:~4,2% %date:~6,2% PassDays
在cmd命令行里输入：date，会显示以上日期格式：
所以上面一句的大概意思就是：获取1-4位为年，5-6位为月份，7-8位为日，但有的日期格式中间的/或者-都会算一位，所以需要多试一下。
本文出自 “Robin's Home” 博客，请务必保留此出处http://winteragain.blog.51cto.com/1436066/911183