asp创建用户、目录和站点

本讲将使用到ADSI，即活动目录服务接口.可以到15Seconds.com找到一些相关的资料.

  1.创建用户
    下面这段代码在独立服务器white上创建用户user1,初始口令user1,用到了ADSI.
    Dim Username,UserPass
    Dim oDomain,oUser
    Username = "user1"
    UserPass = "user1"
    Set oDomain = GetObject("WinNT://white")
    Set oUser = oDomain.Create ("user", UserName)
    If (err.number = 0) Then
        oUser.SetInfo
        oUser.SetPassword UserPass
        oUser.SetInfo
    Else
        WScript.Echo "创建用户" & UserName & "出错！"
    End If
    Set oUser = Nothing
    Set oDomain = Nothing

  2.创建目录
    使用FileSystemObject创建目录:
    Dim FsObject
    Dim tmpFolder
    Set FsObject = WScript.CreateObject("Scripting.FileSystemObject")
    tmpFolder = "D:\userdate\user1"
    If Not FsObject.FolderExists(tmpFolder) Then
        FsObject.CreateFolder(tmpFolder)
        If Err.Number<>0 Then
            WScript.Echo "创建目录" & tmpFolder & "失败！"
        End If
    End If
    注意在创建目录前,先检查了目录是否存在,如果存在,则不用创建了.

  3.创建站点
    下面这个子程序负责创建一个WWW站点,各个参数的意义为：站点IP地址,站点根目录,站点说明,主机名,端口号,计算机名(一搬为LOCALHOST),是否立即启动,匿名访问时所使用的帐号,匿名访问时所用帐号的口令,LOG文件的目录.
    函数返回所建站点在IIS中的序号(在IIS中,所有站点依次编号,第一个为1).
    一个调用示例：siteid = ASTCreateWebSite("10.1.3.122","d:\userdata\user1","www_user1","","80","LocalHost",True,"IUSR_user1","8iui%#","D:\Logfiles")

Function ASTCreateWebSite(IPAddress, RootDirectory, ServerComment, HostName, PortNum, Computer, Start,AnonymousUserName,AnonymousUserPass,LogFileDirectory)
    Dim w3svc, WebServer, NewWebServer, NewDir
    Dim Bindings, BindingString, NewBindings, Index, SiteObj, bDone
        On Error Resume Next
        Err.Clear
        Set w3svc = GetObject("IIS://" & Computer & "/w3svc")
        If Err.Number <> 0 Then
            WScript.Echo "无法打开: "&"IIS://" & Computer & "/w3svc" & VbCrlf & "程序将退出."
            WScript.Quit (1)
        End If

        BindingString = IpAddress & ":" & PortNum & ":" & HostName
        For Each WebServer in w3svc
            If WebServer.Class = "IIsWebServer" Then
                Bindings = WebServer.ServerBindings
                If BindingString = Bindings(0) Then
                    WScript.Echo "IP地址冲突:" & IpAddress & ",请检测IP地址！." & VbCrlf & "取消创建本站点。"
                    Exit Function
                End If
            End If
        Next

        Index = 1
        bDone = False

        While (Not bDone)
            Err.Clear
            Set SiteObj = GetObject("IIS://"&Computer&"/w3svc/" & Index)
            If (Err.Number = 0) Then
                Index = Index + 1
            Else
                Err.Clear
                Set NewWebServer = w3svc.Create("IIsWebServer", Index)
                If (Err.Number <> 0) Then
                    Index = Index + 1
                Else
                    Err.Clear
                    Set SiteObj = GetObject("IIS://"&Computer&"/w3svc/" & Index)
                    If (Err.Number = 0) Then
                        bDone = True
                    Else
                        Index = Index + 1
                    End If
                End If
            End If

            If (Index > 10000) Then
                WScript.Echo "看起来不能创建站点，正在创建的站点的序号为： "&Index&"." & VbCrlf & "取消创建本站点。"
                Exit Function
            End If
        Wend

        NewBindings = Array(0)
        NewBindings(0) = BindingString
        NewWebServer.ServerBindings = NewBindings
        NewWebServer.ServerComment = ServerComment
        NewWebServer.AnonymousUserName = AnonymousUserName
        NewWebServer.AnonymousUserPass = AnonymousUserPass
        NewWebServer.KeyType = "IIsWebServer"
        NewWebServer.FrontPageWeb = True
        NewWebServer.EnableDefaultDoc = True
        NewWebServer.DefaultDoc = "Default.htm, Default.asp, Index.htm, Index.asp"
        NewWebServer.LogFileDirectory = LogFileDirectory
        NewWebServer.SetInfo

        Set NewDir = NewWebServer.Create("IIsWebVirtualDir", "ROOT")
        NewDir.Path = RootDirectory
        NewDir.AccessRead = true
        NewDir.AppFriendlyName = "应用程序" & ServerComment
        NewDir.AppCreate True
        NewDir.AccessScript = True
        Err.Clear
        NewDir.SetInfo
        If (Err.Number = 0) Then
        Else
            WScript.Echo "主目录创建时出错."
        End If
    
        If Start = True Then
            Err.Clear
            Set NewWebServer = GetObject("IIS://" & Computer & "/w3svc/" & Index)
            NewWebServer.Start
            If Err.Number <> 0 Then
                WScript.Echo "启动站点时出错!"
                Err.Clear
            Else
            End If
        End If    
        ASTCreateWebSite = Index
End Function

    下面函数创建ＦＴＰ站点：
Function ASTCreateFtpSite(IPAddress, RootDirectory, ServerComment, HostName, PortNum, Computer, Start,LogFileDirectory)
    Dim MSFTPSVC, FtpServer, NewFtpServer, NewDir
    Dim Bindings, BindingString, NewBindings, Index, SiteObj, bDone
        On Error Resume Next
        Err.Clear
        Set MSFTPSVC = GetObject("IIS://" & Computer & "/MSFTPSVC")
        If Err.Number <> 0 Then
            WScript.Echo "无法打开: "&"IIS://" & Computer & "/MSFTPSVC" & VbCrlf & "程序将退出."
            WScript.Quit (1)
        End If

        BindingString = IpAddress & ":" & PortNum & ":" & HostName
        For Each FtpServer in MSFTPSVC
            If FtpServer.Class="IIsFtpServer" Then
            Bindings = FtpServer.ServerBindings
            If BindingString = Bindings(0) Then
                WScript.Echo "IP地址冲突:" & IpAddress & ",请检测IP地址！." & VbCrlf & "取消创建本站点。"
                Exit Function
            End If
            End If
        Next

        Index = 1
        bDone = False

        While (Not bDone)
            Err.Clear
            Set SiteObj = GetObject("IIS://"&Computer&"/MSFTPSVC/" & Index)
            If (Err.Number = 0) Then
                Index = Index + 1
            Else
                Err.Clear
                Set NewFtpServer = MSFTPSVC.Create("IIsFtpServer", Index)
                If (Err.Number <> 0) Then
                    Index = Index + 1
                Else
                    Err.Clear
                    Set SiteObj = GetObject("IIS://"&Computer&"/MSFTPSVC/" & Index)
                    If (Err.Number = 0) Then
                        bDone = True
                    Else
                        Index = Index + 1
                    End If
                End If
            End If

            If (Index > 10000) Then
                WScript.Echo "看起来不能创建站点，正在创建的站点的序号为： "&Index&"." & VbCrlf & "取消创建本站点。"
                Exit Function
            End If
        Wend

        NewBindings = Array(0)
        NewBindings(0) = BindingString
        NewFtpServer.ServerBindings = NewBindings
        NewFtpServer.ServerComment = ServerComment
        NewFtpServer.AllowAnonymous = False
        NewFtpServer.AccessWrite = True
        NewFtpServer.AccessRead = True
        NewFtpServer.DontLog = False
        NewFtpServer.LogFileDirectory = LogFileDirectory
        NewFtpServer.SetInfo

        Set NewDir = NewFtpServer.Create("IIsFtpVirtualDir", "ROOT")
        NewDir.Path = RootDirectory
        NewDir.AccessRead = true
        Err.Clear
        NewDir.SetInfo
        If (Err.Number = 0) Then
        Else
            WScript.Echo "主目录创建时出错."
        End If
    
        If Start = True Then
            Err.Clear
            Set NewFtpServer = GetObject("IIS://" & Computer & "/MSFTPSVC/" & Index)
            NewFtpServer.Start
            If Err.Number <> 0 Then
                WScript.Echo "启动站点时出错!"
                Err.Clear
            Else
            End If
        End If    
        ASTCreateFtpSite = Index
End Function

时间： 2024-08-02 06:44:40

asp创建用户、目录和站点的相关文章

ASP创建用户,目录和站点

创建|站点 本讲将使用到ADSI,即活动目录服务接口.可以到15Seconds.com找到一些相关的资料. 1.创建用户 下面这段代码在独立服务器white上创建用户user1,初始口令user1,用到了ADSI. Dim Username,UserPass Dim oDomain,oUser Username = "user1" UserPass = "user1" Set oDomain = GetObject("WinNT://white"

asp创建用户、目录和站点(转)

    本讲将使用到ADSI,即活动目录服务接口.可以到15Seconds.com找到一些相关的资料.    1.创建用户    下面这段代码在独立服务器white上创建用户user1,初始口令user1,用到了ADSI.    Dim Username,UserPass    Dim oDomain,oUser    Username = "user1"    UserPass = "user1"    Set oDomain = GetObject("

轻松架设Windows 2003用户隔离FTP站点的注意事项_win服务器

架设FTP站点似乎已经不是什么困难的事情了,我们不需要借助任何外来工具的帮忙,只需要使用Windows服务器系统自带的IIS功能,就能轻易地架设一台FTP站点了.不过,用这种方法架设的FTP站点不但允许任何用户进行匿名访问,而他们也能对FTP站点的主目录进行随意"读取"与"写入",如此一来保存在FTP站点中的内容就没有安全性了.那么我们究竟该怎样才能让架设成功的FTP站点,不允许用户访问主目录.而只能访问用户自己的目录呢?事实上,在Windows 2003服务器的I

用ASP.NET（VB版）创建WINDOWS 2000 SERVER站点

asp.net|server|window|创建|站点 用ASP.NET(VB)创建的WEB站点,我们的调用方式非常简单:Dim test As New Class1()test.CreateWebSit(webname,port, "D:\VB", "localhost") 下面是Class1的代码,该代码做的工作就是建立站点,如果有此站点的名称则自动覆盖(注意:本类需要引用Actice DS Type Library)Public Class Class1 用l

asp.net中用C#实现站点计数器用户控件

asp.net|计数器|控件|站点 ---------------- 资源:同级目录下的存放当前计数的count.txt文件 子目录pic下的0到9的数字图片0.gif ~ 9.gif -------------------------------- asax文件: <%@ Control Language="c#" AutoEventWireup="false" Codebehind="counter.ascx.cs" Inherits=

ASP.NET：目录创建和删除

asp.net|创建     基于B/S结构的信息管理系统中,一般要比普通的网站有更多的技术要求,比如OA系统等.这些系统往往需要直接对系统文件进行操作,比如文件目录的浏览和增删操作.文件的增删操作等.ASP.NET为程序员们提供了丰富的文件操作接口,根据提供的接口可以高效地实现需求中的功能.     ASP.NET中的文件操作主要应用了System.IO命名空间中的几个类:Directory类.file类.StreamReader类等.我们知道,在进行Web方式的系统文件操作时候,像进行数据库

Inno Setup 创建站点，创建虚拟目录

原文 http://hi.baidu.com/0531_sunmiles/item/ce22554ab7d33d0be9350477 下面的这段代码是用Inno Setup 做安装包的时候创建IIS新的站点用的.因为是测试的,所以罗列了很多功能.虽然我现在用不到这么多,还是怕忘记了,做个备份.注释的部分也很宝贵啊. 本文同期发布在 论坛: http://www.jn18178.cn {---IIS部分---}constIISServerName = 'localhost'; IISServerN

iis创建用户隔离模式FTP站点的方法_win服务器

为了方便大家使用,所建立的FTP站点不仅允许匿名用户访问,而且对主目录启用了"读取"和"写入"的权限.这样一来任何人都可以没有约束地任意读写,难免出现一团糟的情况.如果您使用IIS 6.0,只需创建一个'用户隔离'的FTP站点就可以有效解决此问题. "隔离用户"是IIS 6．0中包含的FTP组件的一项新增功能.配置成"用户隔离"模式的FTP站点可以使用户登录后直接进入属于该用户的目录中,且该用户不能查看或修改其他用户的目录.

ASP创建EXCHANGE用户的一段代码

近日逼不得已必须用ASP创建EXCHANGE 2000用户,但以前的相似文章都是关于EXCHANGE 5.5的,而且明确说明不向后兼容,因此在MSDN网站游荡了很久,终于找到一点资料,经过改编,终于能用于ASP. 此段ASP的执行的环境在W2K+IIS5,并且必须要有足够的权限. 如有不当之处,请高手指正. <%@ Language=VBScript %><HTML><HEAD><META NAME="GENERATOR" Content=&q