去除HTML代码中所有标签的两种方法_应用技巧

去除HTML代码中所有标签

复制代码 代码如下:

<%
'******************************
'函数：RemoveHTML_A(strText)
'参数：strText，待处理的字符串
'作者：阿里西西
'日期：2007/7/12
'描述：去除HTML代码中所有标签
'示例：<%=RemoveHTML_A("<b>欢迎光临阿里西西</b>")%>
'******************************
Function RemoveHTML_A(strText)
    Dim nPos1
    Dim nPos2

    nPos1 = InStr(strText, "<") 
    Do While nPos1>0 
        nPos2 = InStr(nPos1+1, strText, ">") 
        If nPos2>0 Then 
            strText = Left(strText, nPos1 - 1) & Mid(strText, nPos2 + 1) 
        Else 
            Exit Do 
        End If 
        nPos1 = InStr(strText, "<") 
    Loop 

    RemoveHTML_A = strText 
End Function
%>

去除HTML代码中所有标签之二

复制代码 代码如下:

<% 
'****************************** 
'函数：RemoveHTML_B(strText) 
'参数：strText，待处理的字符串 
'作者：阿里西西 
'日期：2007/7/12 
'描述：去除HTML代码中所有标签 
'示例：<%=RemoveHTML_B("<b>欢迎光临阿里西西</b>")%> 
'****************************** 
Function RemoveHTML_B( strText ) 
 Dim RegEx 

 Set RegEx = New RegExp 

 RegEx.Pattern = "<[^>]*>" 
 RegEx.Global = True 

 RemoveHTML_B = RegEx.Replace(strText, "") 
End Function 
%> 

去除HTML代码中所有标签之三

复制代码 代码如下:

<%
'******************************
'函数：RemoveHTML_C(strText)
'参数：strText，待处理的字符串
'作者：阿里西西
'日期：2007/7/12
'描述：去除HTML代码中所有标签
'示例：<%=RemoveHTML_C("<b>欢迎光临阿里西西</b>")%>
'******************************
Function RemoveHTML_C( strText )
    Dim TAGLIST
    TAGLIST = ";!--;!DOCTYPE;A;ACRONYM;ADDRESS;APPLET;AREA;B;BASE;BASEFONT;" &_
              "BGSOUND;BIG;BLOCKQUOTE;BODY;BR;BUTTON;CAPTION;CENTER;CITE;CODE;" &_
              "COL;COLGROUP;COMMENT;DD;DEL;DFN;DIR;DIV;DL;DT;EM;EMBED;FIELDSET;" &_
              "FONT;FORM;FRAME;FRAMESET;HEAD;H1;H2;H3;H4;H5;H6;HR;HTML;I;IFRAME;IMG;" &_
              "INPUT;INS;ISINDEX;KBD;LABEL;LAYER;LAGEND;LI;LINK;LISTING;MAP;MARQUEE;" &_
              "MENU;META;NOBR;NOFRAMES;NOSCRIPT;OBJECT;OL;OPTION;P;PARAM;PLAINTEXT;" &_
              "PRE;Q;S;SAMP;SCRIPT;SELECT;SMALL;SPAN;STRIKE;STRONG;STYLE;SUB;SUP;" &_
              "TABLE;TBODY;TD;TEXTAREA;TFOOT;TH;THEAD;TITLE;TR;TT;U;UL;VAR;WBR;XMP;"

    Const BLOCKTAGLIST = ";APPLET;EMBED;FRAMESET;HEAD;NOFRAMES;NOSCRIPT;OBJECT;SCRIPT;STYLE;"

    Dim nPos1
    Dim nPos2
    Dim nPos3
    Dim strResult
    Dim strTagName
    Dim bRemove
    Dim bSearchForBlock

    nPos1 = InStr(strText, "<")
    Do While nPos1 > 0
        nPos2 = InStr(nPos1 + 1, strText, ">")
        If nPos2 > 0 Then
            strTagName = Mid(strText, nPos1 + 1, nPos2 - nPos1 - 1)
     strTagName = Replace(Replace(strTagName, vbCr, " "), vbLf, " ")

            nPos3 = InStr(strTagName, " ")
            If nPos3 > 0 Then
                strTagName = Left(strTagName, nPos3 - 1)
            End If

            If Left(strTagName, 1) = "/" Then
                strTagName = Mid(strTagName, 2)
                bSearchForBlock = False
            Else
                bSearchForBlock = True
            End If

            If InStr(1, TAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
                bRemove = True
                If bSearchForBlock Then
                    If InStr(1, BLOCKTAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
                        nPos2 = Len(strText)
                        nPos3 = InStr(nPos1 + 1, strText, "</" & strTagName, vbTextCompare)
                        If nPos3 > 0 Then
                            nPos3 = InStr(nPos3 + 1, strText, ">")
                        End If

                        If nPos3 > 0 Then
                            nPos2 = nPos3
                        End If
                    End If
                End If
            Else
                bRemove = False
            End If

            If bRemove Then
                strResult = strResult & Left(strText, nPos1 - 1)
                strText = Mid(strText, nPos2 + 1)
            Else
                strResult = strResult & Left(strText, nPos1)
                strText = Mid(strText, nPos1 + 1)
            End If
        Else
            strResult = strResult & strText
            strText = ""
        End If

        nPos1 = InStr(strText, "<")
    Loop
    strResult = strResult & strText

    RemoveHTML_C = strResult
End Function
%>

时间： 2024-09-20 00:10:27

去除HTML代码中所有标签的两种方法_应用技巧的相关文章

去除HTML代码中所有标签的两种方法

去除HTML代码中所有标签 复制代码 代码如下: <% '****************************** '函数:RemoveHTML_A(strText) '参数:strText,待处理的字符串 '作者:阿里西西 '日期:2007/7/12 '描述:去除HTML代码中所有标签 '示例:<%=RemoveHTML_A("<b>欢迎光临阿里西西</b>")%> '****************************** Func

ASP.Net中利用CSS实现多界面的两种方法_实用技巧

本文实例讲述了ASP.Net中利用CSS实现多界面的两种方法.分享给大家供大家参考.具体实现方法如下: 可以通过使页面动态加载不同CSS来实现多界面的效果: 方法一: 复制代码 代码如下: <%@page language="C#"%> <%@import namespace="System.Data"%> <script language="c#" runat="server"> publ

ASP.NET Razor模板引擎中输出Html的两种方式_实用技巧

本文实例讲述了ASP.NET Razor模板引擎中输出Html的两种方式.分享给大家供大家参考,具体如下: Razor中所有的Html都会自动编码,这样就不需要我们手动去编码了(安全),但在需要输出Html时就是已经转义过的Html文本了,如下所示: @{ string thisTest = "<span style=\"color:#f00;\">qubernet</span>"; } @thisTest; 这样在页面输出的文本就是:<

压缩aspx页面删除多余空格的两种方法_实用技巧

两种方法实现: 1)一行一行的读取aspx文件然后处理 2)一次性读取aspx文件然后处理  处理逻辑: 替换"  "为" "(将两个空格替换为一个空格),将所有的换行符替换为空字符(极限压缩) 注意事项: 1)一行一行处理在极限压缩的情况下需要额外的处理服务端控件换行的情况,比如 复制代码 代码如下: Line 1:<asp:Label  runat="server" Line 2: ID="lb1"   .... L

DataGrid中实现超链接的3种方法_实用技巧

1.使用DataGrid中的超链接列-HyperLinkColumn 相信很多人都使用过datagrid中的超链接列,它很好用,默认情况下只能传递一个参数,如下所示: 复制代码 代码如下: <asp:HyperLinkColumn DataTextField="CompanyName" DataNavigateUrlField="CustomerID"     DataNavigateUrlFormatString="Default2.aspx?cu

C# web api返回类型设置为json的两种方法_实用技巧

web api写api接口时默认返回的是把你的对象序列化后以XML形式返回,那么怎样才能让其返回为json呢,下面就介绍两种方法: 方法一:(改配置法) 找到Global.asax文件,在Application_Start()方法中添加一句: 复制代码 代码如下: GlobalConfiguration.Configuration.Formatters.XmlFormatter.SupportedMediaTypes.Clear(); 修改后: 复制代码 代码如下: protected void

asp.net清空Cookie的两种方法_实用技巧

asp.net清空Cookie的两种方法 第一种 Cookie.Expires=[DateTime]; Response.Cookies("UserName").Expires = 0; 第二种 Response.Cookies["admin"].Expires = DateTime.Now.AddDays(-1); 

asp.net实现图片以二进制流输出的两种方法_实用技巧

本文实例讲述了asp.net实现图片以二进制流输出的两种方法.分享给大家供大家参考,具体如下: 方法一: System.IO.MemoryStream ms = new System.IO.MemoryStream(); System.IO.Stream str = new FileUpload().PostedFile.InputStream; System.Drawing.Bitmap map = new System.Drawing.Bitmap(str); map.Save(ms, Sy

获取body标签的两种方法_基础知识

引用body标签有两做法: 第一种:使用DOM Core 即引用某个给定文档的第一个(也是仅有的一个)body标签 复制代码 代码如下: document.getElementsByTagName("body")[0] 第二种:使用HTML-DOM,即引用某个给定文档的body属性: 复制代码 代码如下: doucumnet.body 本文的重点: 1. 哪些是DOM Core,哪些是HTML-DOM(慢慢补充)