asp 读取通过表单发送的post数据

学习ASP，最重要的就是要掌握ASP内置的六大对象。事实上，在上一讲中，我们已经了解了Response对象，及Response对象中最常用的Write方法、Redirect方法和Expires属性。看到对象、方法、属性、集合、事件这些概念（俺一个都不识！），如果以前没接触过，聪明的您就不要管这些概念了，知道怎么用就行了，我的观点是刚开始关键在于临摹。下面我们继续通过实例学习Request对象，为了加深理解，务请运行这些程序看看输出结果。

一、 使用Request.ServerVariables获取环境变量，这部分内容很简单，但获取的内容却很重要，如何获取？请看下例：

复制代码 代码如下:

<%@ Language=VBScript %>

<HTML><BODY>

<% 'wuf8.asp

Response.Write "运行ASP文件的路径: " &_

Request.ServerVariables("Script_Name") & "<Br>"

Response.Write "返回content的数据长度: " &_

Request.ServerVariables("Content_Length") & "<Br>"

Response.Write "返回客户的IP地址: " &_

Request.ServerVariables("Remote_Addr") & "<Br>"

Response.Write "浏览器名: " &_

Request.ServerVariables("HTTP_USER_AGENT") & "<Br>"

Response.Write "返回主页实际物理路径: " &_

Request.ServerVariables("APPL_PHYSICAL_PATH") & "<Br>"

%>

<table colspan=8 cellpadding=5 border=0>

<tr>

<td align=CENTER bgcolor="#800000" width="109"> <font style="ARIAL NARROW" color="#ffffff" size="2">环境变量名</font></td>

<td align=CENTER width=459 bgcolor="#800000"> <font style="ARIAL NARROW" color="#ffffff" size="2">内容</font></td>

</tr>

<tr>

<td bgcolor="f7efde" align=CENTER> <font style="ARIAL NARROW" size="2">

result1

</font></td>

<td bgcolor="f7efde" align=CENTER> <font style="ARIAL NARROW" size="2">

result2

</font></td></tr>

</table>

</BODY></HTML>

Now，你应该发现上一讲中的例程wuf2.asp原来是多么的easy！

注意：该程序的后面一部分HTML标记纯是为下面的例子作准备的，所以不要觉得奇怪。那么，还有哪些环境变量呢？运行下面的例子就知道了（本程序删除了部分代码，最好去我站点下载源程序便于理解）。

复制代码 代码如下:

<%@ Language=VBScript %>

<% ‘wuf9.asp

Option Explicit

Dim Sv

%>

<HTML><BODY>

<table colspan=8 cellpadding=5 border=0>

<tr>

<td align=CENTER bgcolor="#800000" width="109"> <font style="ARIAL NARROW" color="#ffffff" size="2">环境变量名</font></td>

<td align=CENTER width=459 bgcolor="#800000"> <font style="ARIAL NARROW" color="#ffffff" size="2">结果</font></td>

</tr>

<%

for each Sv In Request.ServerVariables

Response.Write "<tr>"

Response.Write "<td bgcolor='f7efde' align=CENTER> <font style='ARIAL NARROW' size='2'>"

Response.Write Sv

Response.Write "</font></td>"

Response.Write "<td bgcolor='f7efde' align=CENTER> <font style='ARIAL NARROW' size='2'>"

Response.Write Request.ServerVariables(Sv)

Response.Write "</font></td></tr>"

next

%>

</table>

</BODY></HTML>

这里使用了For…Each循环，用来列举一个集合中的所有元素。如果后半部分看不懂，请对照wuf8.asp，再瞧瞧运行结果，仔细体会一下（什么态度？）。

二、 通过表单向服务器传送数据（也可这样理解，服务器端如何读取客户端发送的数据）

做过主页，应该知道很多主页通常都使用Form表单让用户输入数据，然后通过“submit（提交）”按钮发送数据。From表单中的“method”有两种主要方法：POST和GET，而“action”后一般都是指定一个.cgi、.pl或.asp文件，今天我们要学习的就是如果编写这个.asp文件。

（一） 如果使用POST方法传送数据，则用Request.Form来读取数据。

先编辑如下一个wuf10.htm文件，供用户输入数据：

复制代码 代码如下:

<html>

<body bgcolor="#FFFFFF">

<form method="post" action="wuf11.asp">

姓名： <input type="text" name="yourname"><br>

性别： <select name="gender">

<option>男</option>

<option>女</option>

</select> <br>

留言： <textarea name="message">您好！

注意多行文本的处理</textarea> <br>

爱好（按住Ctrl键可多选）：

<select name="hobby" multiple size="4">

<option>电脑</option>

<option>购物</option>

<option>电影</option>

<option>读书</option>

</select> <br>

<input type="submit" name="Submit" value="提交">

<input type="reset" name="Submit2" value="Reset">

</form>

</body>

</html>

再编写一个wuf10.htm需用到的文件wuf11.asp收集数据：

复制代码 代码如下:

<%@ Language=VBScript %>

<% 'wuf11.asp

Option Explicit

Response.Expires=0

Dim StrName, StrGender, StrM, StrMsg

StrName = Trim(Request.Form("yourname")) 'Trim函数用来除首尾空格

StrGender = Trim(Request.Form("gender"))

StrM = Trim(Request.Form("message"))

StrMsg = Replace(StrM,vbcrlf,"<Br>" & vbcrlf)

' vbcrlf相当于回车符和换行符的组合。至于Replace函数,其作用就是将字符串StrM中的vbcrlf替换为"<Br>" & vbcrlf（请思考这个vbcrlf有什么用？查看输出文件的HTML源码就明白了），详细请参考VBScript帮助。

%>

<HTML><BODY>

姓名: <%= StrName%><Br><Br>

性别: <%= StrGender%><Br><Br>

留言: <Br><Br>

<%= StrM%><Br><Br>

<%= StrMsg%><Br><Br>

实际上, "提交"按钮的值也被传递: <Br>

<%= Request.Form("Submit")%><Br><Br>

<% '先把上面看懂, 有兴趣再看看如何读取多个选项

Response.Write "共选择爱好项数:" & Request.Form("hobby").Count & "<Br>"

Dim I

For I = 1 to Request.Form("hobby").Count

Response.Write Request.Form("hobby")(I) & "<Br>"

Next

%>

</BODY></HTML>

在这个的例子中，为了便于理解，我们使用了两个程序，实际上只使用一个程序也可以，如果有兴趣请看下面的例程wuf12.asp，有助于加深对环境变量的理解。

复制代码 代码如下:

<%@ Language=VBScript %>

<% 'wuf12.asp

Option Explicit

Response.Expires=0

Dim StrName, StrGender, StrM, StrMsg

If Request.ServerVariables("Content_Length") <> 0 Then

'提交数据后,这个长度就不会是 0, 因此执行下面的语句, 将结果显示出来

'下面一部分实际上是照搬 wuf11.asp

StrName = Trim(Request.Form("yourname"))

StrGender = Trim(Request.Form("gender"))

StrM = Trim(Request.Form("message"))

StrMsg = Replace(StrM,vbcrlf,"<Br>" & vbcrlf)

%>

<HTML><BODY>

姓名: <%= StrName%><Br><Br>

性别: <%= StrGender%><Br><Br>

留言: <Br><Br>

<%= StrM%><Br><Br>

<%= StrMsg%><Br><Br>

<%

Response.Write "共选择爱好项数:" & Request.Form("hobby").Count & "<Br>"

Dim I

For I = 1 to Request.Form("hobby").Count

Response.Write Request.Form("hobby")(I) & "<Br>"

Next

%>

</BODY></HTML>

<%

Else

'当第一次加载页面时,没有提交任何数据,故前面一部分并不执行,而是从这里开始

'这也就是为什么会有两对 <HTML></HTML> 的原因

'下面照搬 wuf10.htm 就行了

'<form method="post" action="wuf11.asp"> 给用环境变量替换掉了, 其实完全一样

Response.Write "看看结果: " & Request.ServerVariables("Script_name") & "<Br>"

%>

<HTML><BODY>

<form method="post" action="<%= Request.ServerVariables("Script_name")%>">

姓名： <input type="text" name="yourname"><br>

性别： <select name="gender">

<option>男</option>

<option>女</option>

</select> <br>

留言： <textarea name="message">您好！

注意多行文本的处理</textarea> <br>

爱好（按住Ctrl键可多选）：

<select name="hobby" multiple size="4">

<option>电脑</option>

<option>购物</option>

<option>电影</option>

<option>读书</option>

</select> <br>

<input type="submit" name="Submit" value="提交">

<input type="reset" name="Submit2" value="Reset">

</form>

</BODY></HTML>

<%End If%>

（二）如果使用GET方法传送数据，则用Request.Querystring来读取数据。

先编辑如下一个wuf13.htm文件，供用户输入数据：

<html>

<body bgcolor="#FFFFFF">

<form method="get" action="wuf14.asp">

英文姓名： <input type="text" name="Ename"> <br>

中文姓名： <input type="text" name="Cname"><br>

性别： <select name="gender">

<option>男</option>

<option>女</option>

</select> <br>

<input type="submit" name="Submit" value="提交">

<input type="reset" name="Submit2" value="Reset">

</form>

</body>

</html>

再编写一个wuf13.htm需用到的文件wuf14.asp收集数据：

<%@ Language=VBScript %>

<% 'wuf14.asp

Option Explicit

Response.Expires=0

Dim StrCname, StrEname, StrGender

StrEname = Trim(Request.QueryString("Ename")) 'Trim函数用来除首尾空格

StrCname = Trim(Request.QueryString("Cname"))

StrGender = Trim(Request.QueryString("gender"))

%>

<HTML><BODY>

英文姓名: <%= StrEname%><Br><Br>

中文姓名: <%= StrCname%><Br><Br>

性别: <%= StrGender%><Br><Br>

看看提交的字符串: <Br>

<%= Request.ServerVariables("Query_String")%>

</BODY></HTML>

为了更好地理解这个程序，你最好先在浏览器中试试例程wuf13.htm的效果，看看输出的结果，你会发现地址栏中长长的字符串似曾相识，如同在Yahoo搜索时看到的差不多。这时，你试着在地址栏中直接输入“http://localhost/wuf14.asp?Ename=Rose&Cname=李二&gender=女”，居然也得到了同样的结果。所以你可以这样看，wuf13.htm的结果就是得到了类似这样的一个带参数的链接。而Request.QueryString则是从http:// 地址的附加参数中读取各个数据。

实际上，当按“提交”按钮后，查询字符串（输入的数据）会以参数的形式附加到URL地址后（各参数间以“&”分隔），达到传递数据的目的。同时，注意浏览器中显示的查询字符串中没有中文，而是不认识的含百分号的乱码，这是因为进行了编码的缘故。最后，与前面一样，这两个程序也可合并为一个程序（例程wuf15.asp,需去我站点下载）。

几点说明：

1． 若使用POST方法提交数据，则Request.ServerVariables("Content_Length")>0。

若使用GET方法提交数据，则Request.ServerVariables("Query_String") <> ""。

2． 弄懂原理后，你完全可以在同一个ASP文件中混合使用Request.Form和Request.QueryString。

3． 如果在一个Form表单中，有几个按钮，你如何确定用户按了哪个按钮？如果留意的话，会发现例程wuf11.asp中有一句，“提交”按钮的值也被传送，而wuf13.htm中生成的查询字符串最后也可以找到类似的值。请注意：只有被按按钮的值被传送，而其他按钮的值为””，这就是判断依据（《中计报》InfoWeb网站有一篇类似文章）。

时间： 2024-09-25 01:49:36

asp 读取通过表单发送的post数据的相关文章

asp 读取通过表单发送的post数据_应用技巧

学习ASP,最重要的就是要掌握ASP内置的六大对象.事实上,在上一讲中,我们已经了解了Response对象,及Response对象中最常用的Write方法.Redirect方法和Expires属性.看到对象.方法.属性.集合.事件这些概念(俺一个都不识!),如果以前没接触过,聪明的您就不要管这些概念了,知道怎么用就行了,我的观点是刚开始关键在于临摹.下面我们继续通过实例学习Request对象,为了加深理解,务请运行这些程序看看输出结果. 一. 使用Request.ServerVariables获

javascript-关于JS读取form表单的问题，form中嵌套table，input标签放入table中

问题描述 关于JS读取form表单的问题,form中嵌套table,input标签放入table中 <html> <head></head> <body> <form id = "form1" name = "form1" action = "b.html" method = "post"> <table id = "tab" name =

asp.net验证表单与javascript验证表单都可以验证表单，如何选择呢？

问题描述 asp.net验证表单与javascript验证表单都可以验证表单,如何选择呢? asp.net验证表单与javascript验证表单都可以验证表单,孰优孰劣,如何抉择? 解决方案 c#表单验证控件可以同时实现客户端验证和后台验证功能,但是他只能验证服务器控件,客户端的表单不能验证,因此如果你要使用post来进行form提交的话就得自己构造post数据有点麻烦.我的建议是如果你使用的是asp.net控件并且利用postback 来触发表单提交的话(就是直接在按钮上添加后台事件.net代

asp.net获取表单的问题

问题描述 asp.net获取表单的问题 用户名:/asp:TextBox 密码:? /asp:TextBox protected void Page_Load(object sender, EventArgs e) { Response.Write("用户名:" + Request.Form["txtname"] + ""); Response.Write("密码:" + Request.Form["txtpassw

使用 springmvc 读取 form 表单元素

问题描述 如题,各位大牛,小弟有一个 html页面的 form表单,内容为name, email, intro 三个元素使用 springmvc读取器内容@RequestMapping(value="/register/", method=RequestMethod.POST)public ModelAndView handleRegisterRequest(HttpServletRequest request, HttpServletResponse response, @Model

ExtJs 备忘录（4）—— Form表单（四） [ 数据提交 ]

前言 忙的时候再一懒.再加上中途没能迅速解决一些问题,所以把文章拖延到了国庆,不过总算是在今天搞定了.这系列文章可能全部完成可能需要继续延后了,有计划继续写视频监控方面的文章,所以尽量合理安排吧 : ) 系列 1. ExtJs 备忘录(1)-- Form表单(一) [ 控件使用 ] 2. ExtJs 备忘录(2)-- Form表单(二) [ 控件封装 ] 3. ExtJs 备忘录(3)-- Form表单(三) [ 数据验证 ] 4. ExtJs 备忘录(4)-- Form表单(四) [ 数据提交

ExtJs 备忘录（3）—— Form表单（三） [ 数据验证 ]

前言 本章主要讲ExtJS表单验证方面,正好趁着周末多写两篇,一边梳理之前用过的代码,一边就地取材补充相关方面的资料,算是温习+补习吧 : ) 系列 1. ExtJs 备忘录(1)-- Form表单(一) [ 控件使用 ] 2. ExtJs 备忘录(2)-- Form表单(二) [ 控件封装 ] 3. ExtJs 备忘录(3)-- Form表单(三) [ 数据验证 ] 推荐 1. ExtJS中表单验证使用自定义vtype示例  2. ExtJs2.0学习系列(5)--Ext.FormPanel之

form表单提交一个对象封装数据，后台action怎么接收？

问题描述 form表单提交一个对象封装数据,后台action怎么接收? form表单提交一个对象封装数据,后台action怎么接收? 解决方案 从request 中获取数据的. 解决方案二: struts2 form 提交http://blog.knowsky.com/255739.htm 解决方案三: Struts2中表单与Action传递数据三种方式 解决方案四: server端通过request接受,貌似有一个方法,getparXXX什么的了 解决方案五: 我看你jsp的input标签命名

myeclipse获取html表单，传递的数据是乱码？如何解决？

问题描述 myeclipse获取html表单,传递的数据是乱码?如何解决? ![ 图片说明](http://img.ask.csdn.net/upload/201508/13/1439469674_358752.png) 解决方案 解决方案二: 你输入的时候没有规定好输入的数据的编码. 解决方案三: 在你的servlet类的处理方法里面有没有加上乱码处理:request.setCharaterEncoding("UTF-8"); response.setContentType(&quo