实例演练ASP+XML编程(3)

四、操作Xml数据的Cls_Person类说明（clsPerson.asp）

Cls_Person类用来完成与联系人信息相关的各种操作，包括添加、修改和删除等等，它使用VBScript编写。Cls_Person包括Id、Name、Nick、Mobile、Tel、Email、QQ和Company属性，对应于XML文件中的Person节点。Cls_Person包括GetInfoFromXml、AddToXml、EditToXml和DeleteFormXml四个主要方法，分别完成获取信息，添加信息，修改信息和删除信息四个功能。

Cls_Person的具体实现如下，


'***************************************************
' 说明：Person类
' 作者：gwd 2002-11-06
' 引用：pub/constpub.asp
'***************************************************

Class Cls_Person

Private m_intId ' Id，对应Person节点在Persons集合中的位置
Private m_strName ' 姓名
Private m_strNick ' 英文名
Private m_strMobile ' 手机
Private m_strTel ' 电话
Private m_strEmail ' 电子邮件
Private m_strQQ ' QQ号
Private m_strCompany ' 所在公司
Private m_strError ' 出错信息

' 类初始化
Private Sub Class_Initialize()
　m_strError = ""
　m_intId = -1
End Sub

' 类释放
Private Sub Class_Terminate()
　m_strError = ""
End Sub

'-----读写各个属性---------------------------

Public Property Get Id
　Id = m_intId
End Property

Public Property Let Id(intId)
　m_intId = intId
End Property

Public Property Get Name
Name = m_strName
End Property

Public Property Let Name(strName)
　m_strName = strName
End Property

Public Property Get Nick
　Nick = m_strNick
End Property

Public Property Let Nick(strNick)
　m_strNick = strNick
End Property

Public Property Get Mobile
　Mobile = m_strMobile
End Property

Public Property Let Mobile(strMobile)
　m_strMobile = strMobile
End Property

Public Property Get Tel
　Tel = m_strTel
End Property

Public Property Let Tel(strTel)
　m_strTel = strTel
End Property

Public Property Get Email
　Email = m_strEmail
End Property

Public Property Let Email(strEmail)
　m_strEmail = strEmail
End Property

Public Property Get QQ
　QQ = m_strQQ
End Property

Public Property Let QQ(strQQ)
　m_strQQ = strQQ
End Property

Public Property Get Company
　Company = m_strCompany
End Property

Public Property Let Company(strCompany)
　m_strCompany = strCompany
End Property

'-----------------------------------------------

' 获取错误信息
Public Function GetLastError()
　GetLastError = m_strError
End Function

' 私有方法，添加错误信息
Private Sub AddErr(strEcho)
　m_strError = m_strError + "＜Div CLASS=""alert""＞" & strEcho & "＜/Div＞"
End Sub

' 清除错误信息
Public Function ClearError()
　m_strError = ""
End Function

' 从Xml中读取指定节点的数据，并填充各个属性
' 需要首先设置Id
Public Function GetInfoFromXml(objXmlDoc)
　Dim objNodeList
　Dim I

　ClearError

　If objXmlDoc Is Nothing Then
　　GetInfoFromXml = False
　　AddErr "Dom对象为空值"
　　Exit Function
　End If

　If CStr(m_intId) = "-1" Then
　　GetInfoFromXml = False
　　AddErr "未正确设置联系人对象的ID属性"
　　Exit Function
　Else
　　I = m_intId - 1 ' 要读取得节点位置
　End If

　' 选择并读取节点信息，赋予各个属性
　Set objNodeList = objXmlDoc.getElementsByTagName("Person")
　If objNodeList.length - m_intId ＞= 0 Then
　　On Error Resume Next
　　m_strName = objNodeList(I).selectSingleNode("Name").Text
　　m_strNick = objNodeList(I).selectSingleNode("Nick").Text
　　m_strMobile = objNodeList(I).selectSingleNode("Mobile").Text
　　m_strTel = objNodeList(I).selectSingleNode("Tel").Text
　　m_strEmail = objNodeList(I).selectSingleNode("Email").Text
　　m_strQQ = objNodeList(I).selectSingleNode("QQ").Text
　　m_strCompany = objNodeList(I).selectSingleNode("Company").Text
　　GetInfoFromXml = True
　Else
　　GetInfoFromXml = False
　　AddErr "获取联系信息发生错误"
　　Set objNodeList = Nothing
　　Exit Function
　End If
　Set objNodeList = Nothing
End Function

' 添加信息到XML文件中
' 需要首先设置好要填充的属性
Public Function AddToXml(objXmlDoc)
　Dim objPerson, objNode

　ClearError

　If objXmlDoc Is Nothing Then
　　AddToXml = False
　　AddErr "Dom对象为空值"
　　Exit Function
　End If

　' 创建Person节点
　Set objPerson = objXmlDoc.createElement("Person")
　objXmlDoc.documentElement.appendChild objPerson

　' 创建各个子节点
　'-----------------------------------------------------
　Set objNode = objXmlDoc.createElement("Name")
　objNode.Text = m_strName
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Nick")
　objNode.Text = m_strNick
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Mobile")
　objNode.Text = m_strMobile
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Tel")
　objNode.Text = m_strTel
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Email")
　objNode.Text = m_strEmail
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("QQ")
　objNode.Text = m_strQQ
　objPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Company")
　objNode.Text = m_strCompany
　objPerson.appendChild objNode
　'-----------------------------------------------------

　Set objNode = Nothing
　Set objPerson = Nothing

　 On Error Resume Next
　objXmlDoc.save Server.MapPath(C_XMLFILE) '保存XML文件
　If Err.Number = 0 Then
　　AddToXml = True
　Else
　　AddToXml = False
　　AddErr Err.Description
　End If
End Function

' 从XML文件中删除数据
' 需要首先设置Id
Public Function DeleteFromXml(objXmlDoc)
　Dim objNodeList, objNode

　ClearError

　If objXmlDoc Is Nothing Then
　　DeleteFromXml = False
　　AddErr "Dom对象为空值"
　　Exit Function
　End If

　If CStr(m_intId) = "-1" Then
　　DeleteFromXml = False
　　AddErr "未正确设置联系人对象的ID属性"
　　Exit Function
　End If

　Set objNodeList = objXmlDoc.getElementsByTagName("Person")
　If objNodeList.length - m_intId ＜ 0 Then
　　DeleteFromXml = False
　　AddErr "未找到相应的联系人"
　　Set objNodeList = Nothing
　　Exit Function
　End If

　On Error Resume Next
　Set objNode = objXmlDoc.documentElement.removeChild(objNodeList(intId-1))
　If objNode Is Nothing Then
　　DeleteFromXml = False
　　AddErr "删除联系人失败"
　　Set objNodeList = Nothing
　　Exit Function
　Else
　　objXmlDoc.save Server.MapPath(C_XMLFILE)
　End If
　Set objNode = Nothing
　Set objNodeList = Nothing

　If Err.Number = 0 Then
　　DeleteFromXml = True
　Else
　　DeleteFromXml = False
　　AddErr Err.Description
　End If
End Function

' 修改XML文件中的数据
' 需要首先设置好Id
Public Function EditToXml(objXmlDoc)
　Dim objPersonList, objOldPerson, objNewPerson, objNode

　ClearError

　If objXmlDoc Is Nothing Then
　　EditToXml = False
　　AddErr "Dom对象为空值"
　　Exit Function
　End If

　If CStr(m_intId) = "-1" Then
　　EditToXml = False
　　AddErr "未正确设置联系人对象的ID属性"
　　Exit Function
　End If

　Set objPersonList = objXmlDoc.getElementsByTagName("Person")
　If objPersonList.length - m_intId ＜ 0 Then
　　DeleteFromXml = False
　　AddErr "未找到相应的联系人"
　　Set objPersonList = Nothing
　　Exit Function
　End If

　Set objOldPerson = objPersonList(m_intId-1) ' 要修改的旧节点

　Set objNewPerson = objXmlDoc.createElement("Person") ' 用来替换旧节点的新节点
　Set objNode = objXmlDoc.createElement("Name")
　objNode.Text = m_strName
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Nick")
　objNode.Text = m_strNick
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Mobile")
　objNode.Text = m_strMobile
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Tel")
　objNode.Text = m_strTel
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Email")
　objNode.Text = m_strEmail
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("QQ")
　objNode.Text = m_strQQ
　objNewPerson.appendChild objNode

　Set objNode = objXmlDoc.createElement("Company")
　objNode.Text = m_strCompany
　objNewPerson.appendChild objNode

　On Error Resume Next
　' 进行替换
　Set objNode = objXmlDoc.documentElement.replaceChild(objNewPerson, objOldPerson)
　If objNode Is Nothing Then
　EditToXml = False
　AddErr "修改联系人失败"
　Set objOldPerosn = Nothing
　Set objNewPerson = Nothing
　Set objPersonList = Nothing
　Exit Function
Else
　objXmlDoc.save Server.MapPath(C_XMLFILE)
End If

Set objOldPerson = Nothing
Set objNewPerson = Nothing
Set objPersonList = Nothing

If Err.Number = 0 Then
　EditToXml = True
Else
　EditToXml = False
　AddErr Err.Description
End If
End Function

End Class
时间： 2024-10-24 04:40:09

实例演练ASP+XML编程(3)的相关文章

实例演练ASP+XML编程

asp+|xml|编程 本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们,还是具备一定的参考价值的. 读者可以通过此实例,了解在ASP(ActiveServerPage)中如何操纵XML文件,并进行数据的各种处理,包括XML节点的建立.修改.删除和保存等等.文中涉及到的技术包括ASP,VB

实例演练ASP+XML编程(1)

本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们,还是具备一定的参考价值的. 读者可以通过此实例,了解在ASP(Active Server Page)中如何操纵XML文件,并进行数据的各种处理,包括XML节点的建立.修改.删除和保存等等.文中涉及到的技术包括ASP,VBScript,DOM

实例演练ASP+XML编程比较全的了第1/2页_应用技巧

本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程 ,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们 ,还是具备一定的参考价值的. 读者可以通过此实例,了解在ASP(Active Server Page)中如何操纵XML文件,并进行数据的各种处理,包括XML节点的建立.修改.删除 和保存等等.文中涉及到的技术包括ASP,VBScript,

实例演练ASP+XML编程(一)

本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们,还是具备一定的参考价值的.

实例演练ASP+XML编程(4)

五.程序首页(default.asp) 调用相应的包含文件和公共函数,格式化XML文件,并进行显示.可以看到,页面Title是可定制的,公共的头部和尾部都做成了相应的包含文件.C_TITLE.C_XMLFILE和C_XSLFILE为公共常量,在constpub.asp文件中定义,至于它们的意义,相信读者可以很容易地明白.这里调用了上面定义的FormatXml函数. <% Option Explicit'*********************************************

实例演练ASP+XML编程(2)

三.格式转换XSL文件说明(Persons.xsl) 例程中使用XSL对XMl数据进行格式化,并以HTML的形式返回到客户端.这个过程也可以放在客户端进行,但考虑到兼容性的问题,例程中采用了在服务器端通过ASP操纵DOM进行格式化的方法. XSL文件的内容如下, <?xml version="1.0" encoding="gb2312"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1

实例分析学习ASP+XML编程

asp+|xml|编程 本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们,还是具备一定的参考价值的. 读者可以通过此实例,了解在ASP(Active Server Page)中如何操纵XML文件,并进行数据的各种处理,包括XML节点的建立.修改.删除和保存等等.文中涉及到的技术包括ASP,

ASP+XML编程实例讲解(1)

本文是一篇实例讲解的文章.作为一个普通的程序员,我深知,一个优秀的例程,对于正在学习编程的人是多么的有帮助.本文中使用的例程,是一个联系信息管理程序,我也是写来以方便自己和朋友们互相联系用的.但麻雀虽小,五脏俱全,相信对正在学习ASP+XML编程的朋友们,还是具备一定的参考价值的. 读者可以通过此实例,了解在ASP(Active Server Page)中如何操纵XML文件,并进行数据的各种处理,包括XML节点的建立.修改.删除和保存等等.文中涉及到的技术包括ASP,VBScript,DOM,X

从基本应用实例快速步入XML编程世界

xml|编程|应用实例 本文介绍3个XML的基本应用实例,旨在带领你快速步入XML编程世界.实例包括:在.NET中使用XML.读取XML文件,插入数据到XML文档中. 在.NET中使用XML 如果使用过MSXML3,那么在.NET应用程序中使用XML将是一个相当简单的过程.即时没有接触过MSXML3,也不要紧,你会发现使用.NET平台提供的相关类也是很容易的一件事情. 有两种主要API可用于访问建立在XML文档中的数据,它们包括只向前的无缓冲存取以及随机存取,而且自始至终都使用到文档对象模型DO