说说对象的复制

以下为引用的内容：
<%
Dim oConn,oRs
Set oConn = Server.CreateObject("ADODB.Connection")
Set ors = Server.CreateObject("ADODB.RecordSet")
oConn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + Server.MapPath("db1.mdb")
Session("conn") = oConn
ors.open "select * from t1",Session("conn"),1,1
    Response.write(oRs(0))
ors.close
Set ors = Nothing
oConn.close
Set oConn = Nothing
%>

这是网上流传的把Connection对象保存在Seesion对象中的代码，注意其中的：Session("conn") = oConn，对象的复制就是这样子的吗？下边我们来验证一下：

以下为引用的内容：
<%
Dim oConn,oRs
Set oConn = Server.CreateObject("ADODB.Connection")
Set ors = Server.CreateObject("ADODB.RecordSet")
oConn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + Server.MapPath("db1.mdb")
Session("conn") = oConn
ors.open "select * from t1",Session("conn"),1,1
    Response.write(Session("conn").ConnectionString)
ors.close
Set ors = Nothing
oConn.close
Set oConn = Nothing
%>

结果出错，提示"缺少对象: 'Session(...)'"！这说明对象并没有复制成功，那Session("conn")是什么类型的呢？我们用TypeName(Session("conn"))来测试下，结果为"String"！出于好奇，我们直接输出Session("conn")看看：

以下为引用的内容：
<%
Dim oConn,oRs
Set oConn = Server.CreateObject("ADODB.Connection")
Set ors = Server.CreateObject("ADODB.RecordSet")
oConn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + Server.MapPath("db1.mdb")
Session("conn") = oConn
ors.open "select * from t1",Session("conn"),1,1
    Response.write(Session("conn"))
ors.close
Set ors = Nothing
oConn.close
Set oConn = Nothing
%>

结果为：

以下为引用的内容：

Provider=Microsoft.Jet.OLEDB.4.0;Password="";User ID=Admin;Data Source=E:\www\db1.mdb;Mode=Share Deny None;
Extended Properties="";Jet OLEDB:System database="";Jet OLEDB:Registry Path="";Jet OLEDB:Database Password="";
Jet OLEDB:Engine Type=5;Jet OLEDB:Database Locking Mode=1;Jet OLEDB:Global Partial Bulk Ops=2;Jet OLEDB:Global 
Bulk Transactions=1;Jet OLEDB:New Database Password="";Jet OLEDB:Create System Database=False;
Jet OLEDB:Encrypt Database=False;Jet OLEDB:Don't Copy Locale on Compact=False;
Jet OLEDB:Compact Without Replica Repair=False;Jet OLEDB:SFP=False

这不是Connection对象的ConnectionString属性值吗？Connection对象默认的属性为ConnectionString，执行Session("conn") = oConn时只是将Connection对象默认属性的值赋给Session("conn")。那为什么用在oRs.open "select * from t1",Session("conn"),1,1也能成功呢？查找资料得出RecordSet对象open方法的第二个参数可以为Connection对象，也可以是数据库连接信息的字符串！Ok了，那在上边例子中的oConn对象完全是多余的，直接用下边代码即可：

以下为引用的内容：
<%
Dim ors
Set ors = Server.CreateObject("ADODB.RecordSet")
Session("conn") = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + Server.MapPath("db1.mdb")
ors.open "select * from t1",Session("conn"),1,1
    Response.write(oRs(0))
ors.close
Set ors = Nothing
%>

结果无错。好了，到现在为止还剩下一个问题没有解决：怎么才是正确的对象复制方法？还是用Set语句：

以下为引用的内容：
<%
Dim oConn,oRs
Set oConn = Server.CreateObject("ADODB.Connection")
Set ors = Server.CreateObject("ADODB.RecordSet")
oConn.open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + Server.MapPath("db1.mdb")
Set Session("conn") = oConn
ors.open "select * from t1",Session("conn"),1,1
    Response.write(Session("conn").ConnectionString)
    Response.write("<br/>")
    Response.write(TypeName(Session("conn")))
ors.close
Set ors = Nothing
oConn.close
Set oConn = Nothing
%>

这次能显示出ConnectionString属性的信息了，结果也显示Session("conn")为Connection对象！

原文：http://www.mzwu.com/article.asp?id=1105

时间： 2024-09-30 03:42:58

说说对象的复制的相关文章

浅谈C++中对象的复制与对象之间的相互赋值_C 语言

C++对象的复制 有时需要用到多个完全相同的对象,例如,同一型号的每一个产品从外表到内部属性都是一样的,如果要对每一个产品分别进行处理,就需要建立多个同样的对象,并要进行相同的初始化,用以前的办法定义对象(同时初始化)比较麻烦.此外,有时需要将对象在某一瞬时的状态保留下来. C++提供了克隆对象的方法,来实现上述功能.这就是对象的复制机制. 用一个已有的对象快速地复制出多个完全相同的对象.如 Box box2(box1); 其作用是用已有的对象box1去克隆出一个新对象box2. 其一般形式为:

PHP动态地创建属性和方法, 对象的复制, 对象的比较,加载指定的文件,自动加载类文件,命名空间_php实例

PHP前言: •动态地创建属性和方法 •对象的复制 •对象的比较 •加载指定的文件 •自动加载类文件 •命名空间 示例 1.类的相关知识点 3(动态地创建属性和方法) class/class3.php <?php /** * 类的相关知识点 3(动态地创建属性和方法) */ // 用于演示如何动态地创建属性(这就是 php 中所谓的重载) class Class1 { // __set 魔术方法,当设置的属性不存在或者不可访问(private)时就会调用此函数 public function _

C++类对象的复制-拷贝构造函数

在学习这一章内容前我们已经学习过了类的构造函数和析构函数的相关知识,对于普通类型的对象来说,他们之间的复制是很简单的,例如: int a = 10; int b =a; 自己定义的类的对象同样是对象,谁也不能阻止我们用以下的方式进行复制,例如: #include <iostream>using namespace std;class Test{public: Test(int temp) { p1=temp; }protected: int p1;};void main(){ Test a(9

C++返回值为对象时复制构造函数不执行怎么破

先说点背景知识,调用复制构造函数的三种情况: 1.当用类一个对象去初始化另一个对象时. 2.如果函数形参是类对象. 3.如果函数返回值是类对象,函数执行完成返回调用时. 在辅导学生上机时,有同学第3点提出异议.有教材上的例题为证: #include <iostream> using namespace std; class Point //Point 类的定义 { public: Point(int xx=0, int yy=0) { x = xx; //构造函数,内联 y = yy; } P

小议Function.apply() 之一------(函数的劫持与对象的复制)_javascript技巧

关于对象的继承,一般的做法是用复制法: Object.extend 见protpotype.js 的实现方法: 复制代码 代码如下: Object.extend = function(destination, source) {    for (property in source) {      destination[property] = source[property];    }    return destination;  }  除此以外,还有一种不太常见的方法:  Functio

jQuery中json对象的复制方式介绍(数组及对象)_jquery

1.jQuery自带的$.map方式 复制代码 代码如下: $.map(json, function (n) { return n; }); 这种方式原来用于复制数组还可以,今天用它复制数组中的某一条记录,发现字段名称丢失了,后来发现了第二种方法. 2.深复制与浅复制 复制代码 代码如下: // 浅层复制(只复制顶层的非 object 元素) var newObject = jQuery.extend({}, oldObject); // 深层复制(一层一层往下复制直到最底层) var newO

js对象的复制继承实例

 代码如下: <script type="text/javascript"> Object.prototype.extend = function(obj){  //在函数里,把obj属性复制到自身  for(var k in obj){   if(obj.hasOwnProperty(k)){    if(this[k] == undefined){     this[k] = obj[k];    }   }  } } var kitty = {color:'yello

复制对象时勿忘其每一个成分

从条款05中我们知道编译器为你提供了一些默认copying函数,而在某些情况下,我们不想要编译器提供的版本,我们自定义copying构造函数和copying assign操作函数,这个时候你无形之中惹恼了我们的编译器,你不用它的东西,它很"生气",于是它就开始复仇:你的实现代码几乎出错时,它就是不告诉你.这里考虑一个类用来表现一个应用用程序事件类型Event: class Event{ public: Event(int id):eventID_(id){ } Event(const

obj-c编程12:复制对象

    好吧,上一篇我怎么也没想到会写那么多字那么少的代码,希望这一篇不会如此哦. 言归正传,对象的复制分为浅复制和深复制,前者只是复制对象的引用,当原对象的内容发生变化时,复制对象的内容也会发生变化,毕竟他们都指向同一个对象啊!有人可能会说了,原对象如果是不可改变对象,不就可以放心的做浅复制了吗?因为不能修改它的值,也就不用担心复制对象的内容改变啦!还是不行哦!我们设想如下情况: #import <Foundation/Foundation.h> #define msg(...) NSLog