Hardware_Info.vbs 获取硬件信息的VBS代码_vbs

复制代码 代码如下:

'Hardware_Info.vbs v1.1 BY: fastslz
On Error Resume Next
Dim WMI,WS,Fso
Set WMI = GetObject("Winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set cOSs = WMI.ExecQuery("Select * from Win32_OperatingSystem")
For Each oOS in cOSs
        OSx = oOS.Caption &" " & oOS.CSDVersion  & vbCrLf
Next
BBx= "————————————主板信息————————————"  & vbCrLf
Set Board = WMI.InstancesOf("Win32_BaseBoard")
Set Bios = WMI.InstancesOf("Win32_Bios")
For Each oBoard In Board
BBx = BBx _
    & "主板名称: " & oBoard.Product &vbTab & oBoard.Version & vbCrLf _
    & "制造厂商: " & oBoard.Manufacturer                    & vbCrLf
Next
For Each oBios In Bios
BBx = BBx _
    & "BIOS厂商: " & oBios.Manufacturer                     & vbCrLf _
    & "BIOS日期: " & FormatDateTime(wDate(Trim(oBios.ReleaseDate)),1)  & vbCrLf _
    & "BIOS版本: " & oBios.SMBIOSBIOSVersion & vbCrLf _
    & "OEM 版本: " & oBios.Version           & vbCrLf
Next
Set Bios = Nothing:Set Board  = Nothing

CPUx = "———————————处理器信息———————————"  & vbCrLf
Set CPUs = WMI.InstancesOf("Win32_Processor")
Set Caches = WMI.InstancesOf("Win32_CacheMemory")
For Each ObjCPU In CPUs
MCS = ObjCPU.MaxClockSpeed :CCS = ObjCPU.CurrentClockSpeed
If ObjCPU.MaxClockSpeed Mod 2 = 1 Then MCS = CCS + 1
If ObjCPU.CurrentClockSpeed Mod 2 = 1 Then CCS = CCS + 1
OC = QOC(CCS,MCS)
If (OC-MCS) >  10 and (OC-MCS) > 0 Then OCLC = "  超频比率: " & FormatPercent((OC-MCS)/MCS)
If (OC-MCS) < -10 and (OC-MCS) < 0 Then OCLC = "  降频比率: " & FormatPercent((OC-MCS)/MCS)
CPUx = CPUx _
     & "CPU 名称: " & Trim(ObjCPU.Name)                & vbCrLf _
     & "CPU 构架: " & ObjCPU.Description               & vbCrLf _
     & "制造厂商: " & ObjCPU.Manufacturer              & vbCrLf _
     & "接口规格: " & ObjCPU.SocketDesignation         & vbCrLf _
     & "CPU 数量: " & ObjCPU.CpuStatus                 & vbCrLf _
     & "核心数量: " & ObjCPU.NumberOfCores             & vbCrLf _
     & "线程数量: " & ObjCPU.NumberOfLogicalProcessors & vbCrLf _
     & "地址位宽: " & ObjCPU.AddressWidth & " Bit"     & vbCrLf _
     & "数据位宽: " & ObjCPU.DataWidth    & " Bit"     & vbCrLf _
     & "CPU 电压: " & ObjCPU.CurrentVoltage / 10 & "V" & vbCrLf _
     & "外部频率: " & ObjCPU.ExtClock  & " MHz"        & vbCrLf _
     & "当前频率: " & OC               & " MHz" & OCLC & vbCrLf _
     & "原始频率: " & MCS              & " MHz"        & vbCrLf _
     & "CPU 使用: " & ObjCPU.LoadPercentage  & "%"     & vbCrLf
Next
Function QOC(CCS,MCS)
    If CCS = MCS Then
        Set wReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
        wReg.GetDWORDValue &H80000002,"HARDWARE\DESCRIPTION\System\CentralProcessor\0","~MHz",strValue
        OC = strValue :Set wReg = Nothing
        Else
        OC = CCS
    End If
    QOC = OC :If QOC Mod 2 = 1 Then QOC = QOC + 1
End Function
For Each ObjCache In Caches
    If objCache.MaxCacheSize > 0  Then
        Select Case objCache.Purpose
        case "L1-Cache"
        CPUx = CPUx & "一级缓存: " & objCache.MaxCacheSize & "KB    (L1数据＋L1缓存)" & vbCrLf
        case "L2-Cache"
        CPUx = CPUx & "二级缓存: " & objCache.MaxCacheSize & " KB" & vbCrLf
        case "L3-Cache"
        CPUx = CPUx & "三级缓存: " & objCache.MaxCacheSize & " KB" & vbCrLf
        End Select
    End If
Next
Set Caches = Nothing:Set CPUs = Nothing

Memx = "————————————内存信息————————————" & vbCrLf
Set Memorys = WMI.InstancesOf("Win32_PhysicalMemory")
Set MemKY = WMI.InstancesOf("Win32_OperatingSystem")
For Each aKY In MemKY
    ZL = aKY.TotalVisibleMemorySize
    KY = aKY.FreePhysicalMemory
Next
Mems = 0:Memc = 0
Types = Array("Unknown","Other","DRAM","Synchronous DRAM","Cache DRAM","EDO","EDRAM","VRAM","SRAM", "RAM", _
               "ROM","Flash","EEPROM","FEPROM","EPROM","CDRAM","3DRAM","SDRAM","SGRAM","RDRAM","DDR","DDR2")
For Each Mem In Memorys
    For i = 0 To UBound(Types)
        If Mem.MemoryType = i Then MemType = Types(i) :End If
    Next
    For j = 0 To 6
        Select Case Mem.Tag
            case "Physical Memory " & j
            Mems = Mems+(Mem.Capacity)
            Memx = Memx  &"插槽" & Mem.DeviceLocator & ": " & Round(Mem.Capacity/1048576) &" MB  " _
                         & MemType & "-" & Mem.Speed & "MHz" & " 数据带宽" & Mem.DataWidth _
                         & "Bit" & " 总带宽" & Mem.TotalWidth &"Bit" & vbCrLf
        End Select
    Next
Next
Memx = Memx _
     & "内存安装: "& Round(Mems/1048576)&" MB " & vbCrLf _
     & "内存总量: "& Round(ZL/1024)& " MB" & vbCrLf _
     & "内存可用: "& Round(KY/1024)& " MB" & vbCrLf _ 
     & "内存使用率: " &FormatPercent((ZL-KY)/ZL)& vbCrLf
Set Memorys = Nothing:Set MemKY = Nothing

Vx= "————————————显卡信息————————————"  & vbCrLf
Set cVID = WMI.ExecQuery("SELECT DeviceID FROM Win32_VideoController")
For Each oVID In cVID
    Set Video = WMI.ExecQuery("SELECT * FROM Win32_VideoController WHERE DeviceID='"& oVID.DeviceID &"'")
    For Each oVideo In Video
        Vx = Vx _
        & "显卡名称: " & oVideo.Name                                    & vbCrLf _
        & "制造厂商: " & oVideo.AdapterCompatibility                    & vbCrLf _
        & "物理显存: " & Round(oVideo.AdapterRAM/1048576)&" MB "        & vbCrLf _
        & "显示模式: " & oVideo.CurrentHorizontalResolution &" X " _
                       & oVideo.CurrentVerticalResolution   &" "_
                       & oVideo.CurrentBitsPerPixel         &"Bit " _
                       & oVideo.CurrentRefreshRate          &"Hz"     & vbCrLf
    Next
Next
Set Video = Nothing:Set cVID = Nothing

Dx= "————————————硬盘信息————————————"  & vbCrLf
Set IDE = WMI.ExecQuery("Select * from Win32_DiskDrive WHERE InterfaceType='IDE'")
Set cPPP = WMI.ExecQuery("SELECT * FROM Win32_PerfRawData_PerfDisk_PhysicalDisk")
For Each oIDE In IDE
    For i = 0 To IDE.Count
        Select Case oIDE.Index
            Case i
               For Each oPPP In cPPP
                   If InStr(oPPP.Name, i) Then vName = oPPP.Name
               Next
               Dx = Dx & "硬盘" & i &"型号:" & oIDE.Caption                   & vbCrLf _
               & vbTab & "标称容量: "    & Round(oIDE.Size/1000000000) &" GB" & vbCrLf _
               & vbTab & "实际容量: "    & Round(oIDE.Size/1073741824) &" GB" & vbCrLf _
               & vbTab & "柱面数: "      & oIDE.TotalCylinders                & vbCrLf _
               & vbTab & "磁头数: "      & oIDE.TotalHeads                    & vbCrLf _
               & vbTab & "每道扇区数: "  & oIDE.SectorsPerTrack               & vbCrLf _
               & vbTab & "扇区大小: "    & oIDE.BytesPerSector                & vbCrLf _
               & vbTab & "总扇区数: "    & oIDE.TotalSectors                  & vbCrLf _
               & vbTab & "分区状态: "    & vName  & vbCrLf
               DevID = Replace(oIDE.DeviceID, "\", "\\")
               Set cDP = WMI.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID="""& DevID &"""}" _
               & "WHERE AssocClass = Win32_DiskDriveToDiskPartition")
               For Each oDP In cDP
                 Set cLD = WMI.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID="""& oDP.DeviceID &"""}" _
                 & "WHERE AssocClass = Win32_LogicalDiskToPartition")
                   For Each oLD In cLD
                     Dx = Dx _
                        & vbTab & oLD.DeviceID &" " & Left(oLD.VolumeName&"         " ,11) & Left(oLD.FileSystem&"   " ,6) & "共:" _
                        & Right("    "&Round(oLD.Size/1073741824,1),6)                &" GB    可用:" _
                        & Right("    "&Round(oLD.FreeSpace/1073741824,1),6)           &" GB    已用:" _
                        & Right("    "&Round((oLD.Size-oLD.FreeSpace)/1073741824,1),6)&" GB" & vbCrLf
                   Next
              Next
        End Select
    Next
Next
Set cLD = Nothing:Set cDP = Nothing:Set IDE = Nothing:Set cDP = Nothing:Set cPPP =  Nothing

Sx= "————————————声卡信息————————————"  & vbCrLf
Set cSD = WMI.ExecQuery("SELECT * FROM Win32_SoundDevice")
For Each oSD In cSD
    Sx = Sx & "声卡名称: " & oSD.ProductName  & vbCrLf
Next
Set cSD = Nothing
Nx= "————————————网卡信息————————————"  & vbCrLf
Set cNet = WMI.ExecQuery("Select * from Win32_NetworkAdapter WHERE PhysicalAdapter ='TRUE'")
If CStr(cNet.Count) < 0 Then
    Set cNet = WMI.ExecQuery("Select * from Win32_NetworkAdapter WHERE PNPDeviceID Like 'PCI%%' or PNPDeviceID Like 'USB%%'")
    For Each oNet In cNet
        If oNet.NetConnectionStatus > 0 Then
           Nx = Nx & "网卡名称: "& oNet.Name & vbCrLf
           Else
           Nx = Nx & "网卡名称: "& oNet.Name & vbCrLf
        End If
    Next
    Else
    For Each oNet In cNet
        If oNet.NetEnabled = TRUE Then
           Nx = Nx & "网卡名称: "& oNet.Name & vbTab & "活跃状态" & vbCrLf
           Else
           Nx = Nx & "网卡名称: "& oNet.Name & vbTab & "空闲状态" & vbCrLf
        End If
    Next
End If
Set cNet = Nothing

If (Lcase(Right(Wscript.FullName,11)) = "wscript.exe") Then
    MsgBox OSx & BBx & CPUx & Memx ,,"Hardware_Info.vbs v1.0 BY: fastslz"
    MsgBox Vx & Sx & Nx  ,,"Hardware_Info.vbs v1.0 BY: fastslz"
    MsgBox Dx ,, "Hardware_Info.vbs v1.0 BY: fastslz"
    MsgN = MsgBox ("是否保存到文件？" , 32+4 , "Hardware_Info.vbs v1.0 BY: fastslz")
    If MsgN = 6 Then JZCSx = JZCS :wInfo
    Else
    WScript.Echo OSx & BBx & CPUx & Memx & Vx & Sx & Nx & Dx
End If
Set WMI = Nothing

Sub wInfo()
    Set WS = CreateObject("WScript.Shell")
    Set Fso = CreateObject("Scripting.FileSystemObject")
    aFile = WS.CurrentDirectory &"\"& WS.ExpandEnvironmentStrings("%COMPUTERNAME%")&"_Hardware_Info.txt"
    Set HInfo = Fso.CreateTextFile(aFile , True)
    HInfo.WriteLine "Hardware_Info.vbs BY: fastslz"
    HInfo.WriteLine OSx & BBx & CPUx & Memx & Vx & Sx & Nx & Dx & JZCSx
    HInfo.Close
    WS.Run Chr(34) & aFile & Chr(34)
Set WS = Nothing:Set Fso = Nothing:Set HInfo = Nothing
End Sub

Function wDate(nD)
    If Not IsNull(nD) Then
    wDate = CDate(Mid(nD,5,2)&"/"&Mid(nD,7,2)&"/"&Left(nD,4)&" "&Mid(nD,9,2)&":"&Mid(nD,11,2)&":"&Mid(nD,13,2))
    End If
End Function

Function JZCS()
    NumMsg = vbCrLf & "———————————简易CPU基准测试———————————" & vbCrLf
    Dim I,T1,T2,Tempvalue,aRunTime,bRunTime
    T1 = Timer()
    For I = 1 To 2000000
        Tempvalue= 2^0.5
    Next
    T2 = Timer()
    aRunTime = FormatNumber((T2-T1)*1000,2)
    NumMsg =  NumMsg & "CPU 200万次开方计算所需时间：" &aRunTime&" 毫秒" & vbCrLf
    T1 = Timer()
    For I = 1 To 6000000
        Tempvalue= 1 + 1
    Next
    T2 = Timer()
    bRunTime = FormatNumber((T2-T1)*1000,2)
    NumMsg =  NumMsg & "CPU 600万次加法计算所需时间："&bRunTime&" 毫秒" & vbCrLf
    JZCS = NumMsg
End Function

cmd调用方法

复制代码 代码如下:

@echo off
for /f "delims=*" %%a In ('Cscript //Nologo "Hardware_Info.vbs"^|find ":"') do echo %%a

:在第二个硬盘第一个分区新建Backup文件夹
for /f "tokens=2,*" %%a In ('Cscript //Nologo "Hardware_Info.vbs"^|findstr  "分区状态"') do (
    if %%a#==1# for /f "tokens=1" %%i In ("%%b") do MD "%%i\Backup")
pause

时间： 2024-10-15 05:21:05

Hardware_Info.vbs 获取硬件信息的VBS代码_vbs的相关文章

vbs获取当前时间日期的代码_vbs

获取当前日期方法一: 复制代码 代码如下: Currentdate1=date()msgbox Currentdate1 获取当前日期方法二: 复制代码 代码如下: Currentdate2=year(Now)&"-"&Month(Now)&"-"&day(Now)msgbox Currentdate2 获取当前时间: 复制代码 代码如下: CurrentTime=Hour(Now)&":"&Min

用VBS获取Unix时间戳的函数代码_vbs

VBS中没有类似C标准库中的time函数,怎么获取Unix时间戳呢?乍一看很简单: 复制代码 代码如下: Function UnixTime() UnixTime = DateDiff("s", "01/01/1970 00:00:00", Now()) End Function 一个很想当然的方法,仅仅注意到了"1970年1月1日0时0分0秒",而忽略了"协调世界时". 协调世界时,又称世界标准时间或世界协调时间,简称UTC

VBS获取重定向的URL的代码_vbs

某个人问的问题: 我本来想获取aaa.com页面的内容,可是aaa.com跳转到bbb.com了.我想获取bbb.com 这个网址. 访问了一下他所谓的aaa.com,发现是HTTP 302重定向 复制代码 代码如下: HTTP/1.1 302 Moved Temporarily Server: nginx/0.8.53 Date: Fri, 08 Apr 2011 15:49:25 GMT Content-Type: text/html;charset=utf-8 Transfer-Encod

WMI 获取硬件信息的封装函数与获取联想台式机的出厂编号方法

原文:WMI 获取硬件信息的封装函数与获取联想台式机的出厂编号方法 今天玩了一把WMI,查询了一下电脑的硬件信息,感觉很多代码都是可以提取出来的,就自己把那些公共部分提出出来,以后如果要获取 某部分的硬件信息就不用写一个一个的函数,比如获取MAC地址就写一个获取MAC地址的函数,获取CPU 信息就写一个获取CPU信息的 函数,太麻烦了 如下是函数代码: 1 private static string identifier(string wmiClass, string wmiProperty,

显示系统信息与硬件信息的bat代码_DOS/BAT

显示系统信息的dos命令,使用批处理显示硬件信息的批处理 这个得看你需要查看的方式. 1. cmd窗口查看 2. 程序窗口查看 3. 文本查看 方法1. cmd窗口查看: @echo off systeminfo dxdiag /dontskip /whql:off /t systeminfo1.txt&&more systeminfo1.txt pause 方法2. 程序窗口查看: @echo off msinfo32 dxdiag pause 方法3. 文本查看: @echo off

vbs后台运行bat删除自身的代码_vbs

知道真实路径的情况下 复制代码 代码如下: set fso=wscript.createobject("scripting.filesystemobject") fso.deletefile "c:\windows\system32\run.cmd" fso.deletefile "c:\windows\system32\run.vbs" 不知道具体的路径情况下,可以用如下代码: 复制代码 代码如下: Set fso =CreateObject(

php获取服务器信息的实现代码_php技巧

复制代码 代码如下: <html><head><meta http-equiv="content-type" content="text/html; charset=gb2312"><title>获取服务器信息</title></head><body><?php$sysos = $_SERVER["SERVER_SOFTWARE"];      //获取服务

vbs 获取当前目录文件数量的代码(不包括子文件夹中的)_vbs

复制代码 代码如下: i=0set fso=CreateObject("Scripting.FileSystemObject")set fs=fso.getfolder(".").filesfor each f in fsi=i+1nextmsgbox "文件总数:"&i

vbs定时发送邮件的方法与代码_vbs

'用VBS写个脚本,然后用WINDOWS平台下的计划任务来调用,每天定时群发邮件.  '代码如下:  下载地址 http://www.51tiao.com/info.vbs 复制代码 代码如下: Dim connstr,conn  Dim sql,rs,msg  Sub OpenDB()      ConnStr = "DSN=51tiao.Com;UID=sa;PWD=;"      If Not IsObject(Conn) Then          Set conn = Cre