第一步是要画一个水珠，新建一个影片剪辑元件，用放射填充画一个椭圆，左色标为白色，透明度100%，右色标略带点灰色，透明度50%。在属性面板中设置椭圆在宽为2像素，高为5像素。在库中右击该元件，打开连接窗口，（cs4打开属性窗口），设置一个类名，我设的是 pall。
接下来回到主场景，打开帧动作面板，我们来写代码。
喷泉是由若干水珠形成的，多少呢？我整了500个：
var count:int = 500;
重力速度向量：
var zl:Number = 0.5;
将这500个水珠放到一个数组中：
var balls:Array;
balls = new Array();
用一个for循环来将500个水珠放到数组中：
for (var i:int = 0; i < count; i++) {
var ball:pall = new pall();
将水珠定位到水珠的喷射口：
ball.x = 260;
ball.y = 200;
在x轴方向也设一个速度向量，使水珠在x轴的一定范围内，并将这个速度向量存到每个水珠的自定义属性vx中：
ball["vx"]= Math.random() * 2 - 1;
下面是y轴方向的速度向量，将它存在自定义属性vy中：
ball["vy"] = Math.random() * -10 - 10;
将水珠放到舞台上，并存到数组中：
addChild(ball);
balls.push(ball);
接下来侦听ENTER_FRAME事件，实现喷泉效果：
addEventListener(Event.ENTER_FRAME, onEnterFrame);
onEnterFrame函数内容：
通过一个for循环为数组中的水珠加上各个速度向量：
for (var i:Number = 0; i < balls.length; i++) {
var ball:pall = pall(balls);
首选在喷射速度向量上加上重力速度向量，这样每一帧的时间就会加一次重力，而喷射力却没变，这样重力就会逐渐超过喷射力面使水珠下落：
ball["vy"] += zl;
将x,y轴速度向量加到水珠上：
ball.x +=ball["vx"];
ball.y +=ball["vy"];
接下来的是看水珠是否超出了舞台，如果超出了舞台，则将水珠重新定位到喷射口，并将速度向量设为初始状态。
if (ball.x - ball.width/2> stage.stageWidth ||
ball.x + ball.width/2 < 0 ||
ball.y - ball.width/2 > stage.stageHeight ||
ball.y + ball.width/2 < 0) {
ball.x = 260;
ball.y = 200;
ball["vx"]= Math.random() * 2 - 1;
ball["vy"] = Math.random() * -10 - 10;
完整代码：
var count:int = 500;
var zl:Number = 0.5;
var balls:Array;
balls = new Array();
for (var i:int = 0; i < count; i++) {
var ball:pall = new pall();
ball.x = 260;
ball.y = 200;
ball["vx"]= Math.random() * 2 - 1;
ball["vy"] = Math.random() * -10 - 10;
addChild(ball);
balls.push(ball);
}
addEventListener(Event.ENTER_FRAME, onEnterFrame);
function onEnterFrame(event:Event):void {
for (var i:Number = 0; i < balls.length; i++) {
var ball:pall = pall(balls[i]);
ball["vy"] += zl;
ball.x +=ball["vx"];
ball.y +=ball["vy"];
if (ball.x - ball.width/2> stage.stageWidth ||
ball.x + ball.width/2 < 0 ||
ball.y - ball.width/2 > stage.stageHeight ||
ball.y + ball.width/2 < 0) {
ball.x = 260;
ball.y = 200;
ball["vx"]= Math.random() * 2 - 1;
ball["vy"] = Math.random() * -10 - 10;
}
}
}
看一下效果