本文是我（aw）在整理了相关文档和讨论之后，结合自己的亲自实验总结出来的一些经验和心得。我尽量描述详尽，避免模糊概念，当然也希望所有看官提出批评意见。为了表述方便，其中术语不限定语言，如我可能会一会儿用class，一会儿用“类”。
面向对象的难点部分就是理解变量作用域修饰符（modifier）其实也就是面向对象中我们已经熟悉的public、protected、private等等。本文还深入讨论了ActionScript3中新增的internal等概念。下面我依次列出：
一、关于package以及internal
package，用“形而上学”的方式理解，就是物理目录下的类集合。在AS2中只需要保证文件系统的路径匹配，然后用类似“import com.awflasher.someUtils”的方法导入即可。而AS3则要求您在所有的类中声明package关键词。package的大括号对 “{}”内，我们只能定义一个类，我们可以在这个大括号外面定义一些辅助类，不过这些类只能被当前这个类（你在package大括号对内定义的类）访问。当然，一个package大括号对内只有一个类，这并不代表一个package内只有一个类。你可以在同一目录下定义多个属于该package（指代这个目录）的类。它的意义绝不是简单的“类文件集合容器”，而是一个让各种应该协同工作的类集中到一起的项目包。值得一提的是，所谓“协同工作”是指至少有一个class要引入其他一些class 来进行功能设计，而这时候采用internal修饰可以省去很多getters和setters。我自己回忆起在湖南卫视的项目中用AS2开发的 Vplayer，两个类AVCore和AVControl就有很多getter和setter，搞的特别麻烦。
internal类似public，但限定在一个 package内了。在同一个package内的类可以访问同一个package内其他类的internal变量，而其他包内的类无法访问。 package 与类的继承性毫无关系，比如TextField和Sprite、MovieClip都继承自DisplayObject类，但TextField属于 flash.text包，而MovieClip和Sprite属于flahs.display包。也就是说，包对类的限定是与继承链毫无关联的、一个新的 “维度”的限定。
附：使用一个类的时候，我们必须import这个类，或者包含这个类的package。AS2时直接写完整包路径的使用方法在AS3中不管用了，本文后面有详细介绍。
二、关于public
public定义的类或者属性可以在任何作用域内由任何来源访问。构造函数永远都是public的，Flex中的应用程序类（Application Class）和Flash CS3中的文档类（Document Class）必须是public的。且不能缺省public这个关键词声明。我在测试中发现，如果不声明public，Flash根本就不会获取类的定义，进而编译无法通过。
三、关于protected
protected声明类似AS2的private，它定义的属性只能在自己子类中可见，而其它场合都是不可见的。这一点与Java等传统OOP语言类似。
四、关于private
注意AS3的private和AS2的private大不相同，它定义的属性只属于自己，子类可以定义毫无牵连的同名属性。
dynamic 和原来AS2的dynamic一样，用dynamic声明的类可以动态的加入属性。这些属性也可以通过delete来删除。动态加入的属性一旦被切断所有的引用就会被垃圾回收机制自动回收。有时候用System.totalMemory检测不到内存释放是因为垃圾回收机制并不是即时运行的。
五、关于dynamic
动态（dynamic）类允许在运行时动态地添加属性，常见的动态类有MovieClip和顶级（top-level）的Array。如果您的自定义类要继承于动态类，那么请也定义为动态的，不要省略dynamic关键词。
六、关于继承（extends）和override
继承其实并不太复杂，唯一要说明的就是：子类的构造函数一定要用“super”调用一次父类的构造函数，否则报错！对于继承后的子类，如果要重新定义父类的非private方法，必须使用override关键词。在override的时候，如果我们需要调用父类的方法，可以使用super关键词（由于继承方法在逻辑上与父类往往有相似性，因此没有必要把方法逻辑完全重写）官方帮助中的这个例子非常易懂：
package {
import flash.display.MovieClip;
public class SuperExample extends MovieClip
{
public function SuperExample()
{
var myExt:Extender = new Extender()
trace(myExt.thanks()); // output: Mahalo nui loa
}
}
}
class Base {
public function thanks():String
{
return “Mahalo”;
}
}
class Extender extends Base
{
override public function thanks():String
{
return super.thanks() + ” nui loa”;
}
}
override不能用于重载变量（成员属性）。但是却可以用于重写getter和setter函数，例如：（官方帮助的例子）
package
{
import flash.display.MovieClip;
public class OverrideExample extends MovieClip
{
public function OverrideExample()
{
trace(currentLabel)
}
override public function get currentLabel():String
{
var str:String = “Override: “;
str += super.currentLabel;
return str;
}
}
}
这个例子中，我们直接重写了MovieClip类的currentLabel属性。注意调用父类属性的时候，用了super.currentLabel。
关于静态方法，比较麻烦。首先，静态方法是无法被重载的。必须通过类来访问。但是您也可以自己定义与静态方法同名的方法，我把官方的例子做了一下修改就一目了然了：
package
{
import flash.display.MovieClip;
public class StaticExample extends MovieClip
{
public function StaticExample()
{
var myExt:Extender = new Extender();
}
}
}
class Base {
public static var test:String = “static”;
}
class Extender extends Base
{
private var test:String = “instance”;
public function Extender()
{
trace(Base.test); // output: static
trace(test); //added by awflasher.com, output: instance
}
}
七、关于import语法
在AS2时代，“import”语法只是为了让编程时代码简洁（省去了包名），比如我们import了mx.transitions.Tween之后，就可以直接new Tween()了。而如果不import，我们也可以直接用全类名来构造实例，例如：new mx.transitions.Tween();
然而，在AS3中，无论是否采用全名类声明，只要你用到这个类，就必须import。import估计是传统Flash程序员所需要养成的一个最大的习惯，在刚切入AS3开发平台的时候，我常常忘记import一些常用的类，例如从IDE 指向过来的文本和渲染元件，以及flash.event.*、flash.display.StageAlign等比较泛用的类。
AS3中不像AS2那样，我们不能用_root和Stage[”displayState”]来进行hacks了。
八、关于编译时的注意事项
AS3不再像AS2那样简单地Complie-Time（编译时，即FlashCS3/FlexBuidler/其他编译器发布ActionScript 及所有资源为SWF文件的那一时刻）进行类型检测了，AS3在Run-Time（运行时，级Flashplayer或者其他播放SWF的软件在播放SWF 的时候）也有类型检测，因此AS2的Hacks（强制访问不能访问的属性）将不再有效。
九、一个不得不说的好消息
AS3中类所有的变量（属性）和函数（方法）的作用域都是运行时跟类/实例走的。这与AS2大有不同，我们不再需要去Delegate了。只要是类自己的方法，在调用的过程中，this永远指向类自己（实例）。
简要总结：
1、如果我需要属性公开，并且可以被自己的子类继承，那么定义成public的。子类也可重写（override）之。
2、如果我需要属性隐藏，但是可以被自己的子类继承，那么定义成protected的。与public类似，子类也可重写（override）之。
3、如果我的某一个类有一个属性不想在任何位置可见，包括其子类，那么定义为private的。其子类无需重写（override），因为它根本就不存在于子类中。